time or gmtime gives you a current timestamp. If you don't care too much about exactness, you can just decrement it by 24*40*3600 to get a date roughly 40 days before.Time::Local converts from a unix epoch timestamp to the usual time tuple. POSIX::strftime is quite convenient for formatting time tuples.

If you want to be exact, you can either use DateTime, or if you want to avoid DateTime, subtract 22 hours worth of seconds from your timestamp in a loop, and exit that loop once the date part of your day has changed 40 times.

How do you define "previous" in "previous business week"? I'm going to assume you want the last M-F in which the current day is not a member.

use strict;
use warnings;

use DateTime     qw( );
use Text::CSV_XS qw( );

my $today = DateTime->today( time_zone => 'local' );
my $dow = $today->dow();

my $last_fri = $today->subtract(
    days => ( $dow <= 5 ? $dow-5+7 : $dow-5 )
);

my $last_mon = $last_fri->subtract(
    days => 4,
);

my $start = $last_fri->strftime("%Y%m%d00");
my $end   = $last_mon->strftime("%Y%m%d99");

my $csv = Text::CSV_XS->new();
while (<$fh_in>) {
    $csv->parse($_)
       or die("csv: " . $csv->error_diag() . "\n");

    my ($ts) = $csv->fields();
    next if $ts lt $start || $ts gt $end;

    print $fh_out $_;
}
[download]

Since your dates are in YYYYMMDDHH format you can use string comparisons to decide whether the datum is in the correct range. This script decrements the current epoch time value by the relevant number of seconds needed to go back to the Friday of the previous week and then another four days to get to the Monday. It then constructs start and end timestamp strings for hour 0 of the Monday and hour 23 of the Friday.

use strict;
use warnings;

my %daysOffsetTV = (
   0 => 86400 * 2,
   1 => 86400 * 3,
   2 => 86400 * 4,
   3 => 86400 * 5,
   4 => 86400 * 6,
   5 => 86400 * 7,
   6 => 86400,
   );

my $nowTV = time();
my $dayOfWk = ( localtime( $nowTV ) )[ 6 ];

my $prevWkFriTV = $nowTV - $daysOffsetTV{ $dayOfWk };
my( $friDay, $friMth, $friYr ) =
   ( localtime( $prevWkFriTV ) )[ 3 .. 5 ];
$friMth += 1;
$friYr  += 1900;
my $endDate =
   sprintf q{%04d%02d%02d%02d}, $friYr, $friMth, $friDay, 23;

my $prevWkMonTV = $prevWkFriTV - 86400 * 4;
my( $monDay, $monMth, $monYr ) =
   ( localtime( $prevWkMonTV ) )[ 3 .. 5 ];
$monMth += 1;
$monYr  += 1900;
my $startDate =
   sprintf q{%04d%02d%02d%02d}, $monYr, $monMth, $monDay, 0;

print
   qq{Starting date: $startDate\n},
   qq{  Ending date: $endDate\n\n};

while( <DATA> )
{
    my $timestamp = ( split m{,} )[ 0 ];
    print
       unless $timestamp lt $startDate or $timestamp gt $endDate;
}

__END__
2009030822,3558,1.68
2009030823,6385,5.47
2009030900,7485,1.82
2009030901,8563,4.35
2009031322,8860,3.68
2009031323,39224,14.16
2009031400,34553,7.34
2009031401,7353,5.74
[download]

The output.

Starting date: 2009030900
  Ending date: 2009031323

2009030900,7485,1.82
2009030901,8563,4.35
2009031322,8860,3.68
2009031323,39224,14.16
[download]

I hope this is of interest.

Cheers,

JohnGG

Not all days have 86400 seconds. Looks like it can fail near a daylight savings time change (by getting Su-Th or Tu-Sa instead of M-F, I think).

Date::Manip also has nice functions for manipulating dates.

#!/usr/bin/perl
use strict;
use warnings;

use Date::Manip;
use Text::CSV_XS qw( );

my $end = UnixDate("last Friday", "%Y%m%d23");
my $start = UnixDate(DateCalc("last Friday", "- 4 days"), "%Y%m%d00");

my $csv = Text::CSV_XS->new();
while (<$fh_in>) {
    $csv->parse($_)
       or die("csv: " . $csv->error_diag() . "\n");

    my ($ts) = $csv->fields();
    next if $ts lt $start || $ts gt $end;

    print $fh_out $_;
}
[download]

Thanks for all your help with this guys. Will have a play with the various methods and see how I get on :)

#!/usr/bin/perl

use strict;
use Date::Calc qw(:all);

while( <DATA> ) {
    my $old_data = $_;
    my ($old_date) = $_ =~ /^(\d{8})\d+,.*/;
    my ($year, $month, $day) = $old_date =~ /(\d{4})(\d{2})(\d{2})/;
    my $dow = Day_of_Week( $year, $month, $day );
    print "$old_data" if ( $dow >= 1 && $dow <= 5 );
}

__DATA__
2009030822,3558,1.68
2009030823,6385,5.47
2009030900,7485,1.82
2009030901,8563,4.35
2009031322,8860,3.68
2009031323,39224,14.16
2009031400,34553,7.34
2009031401,7353,5.74
2009032107,8860,3.68
[download]

That will get business days only but it will get more than just the last week of the 40 days of history in the data file.