Note that in Perl 6 => constructs a Pair, it's not the same as a comma.

Assuming that you have a flat list, and not a list of pairs, it'll look like this in diplomatic idiomatic Perl 6:

my $in = [ one => 1, two => 2, two => '2.003' ];
my %h;

for @$in -> $k, $v {
    %h{$k}.push: $v;
}
[download]

(not golfed).

Rakudo doesn't support this kind of autovivification yet, so the .push on the empty hash bucket fails. However this works in Rakudo:

use v6;

my $in = [ 'one', 1, 'two', 2, 'two', '2.003' ];
my %h;

for @($in) -> $k, $v {
    if %h{$k} {
        %h{$k}.push: $v;
    } else {
        %h{$k} = [ $v ];
    }
}

say %h.perl;

# output:
# {"one" => [1], "two" => [2, "2.003"]}
[download]

if $in is an Array of pairs instead, you can loop over them, and access .key and .value (a method call with a leading dot but no invocant defaults to $_):

use v6;

my $in = [ one => 1, two => 2, two => '2.003' ];
my %h;

for @($in) {
    if %h{.key} {
        %h{.key}.push: .value;
    } else {
        %h{.key} = [ .value ];
    }
}

say %h.perl;

# vim: ft=perl6 sw=4 ts=4 expandtab
# same output
[download]

Again, a complete Perl 6 implementation would allow it shorter like this:

%h{.key}.push: .value for @$in:
[download]

Even nicer, but also not yet implement is

my %h = $in.classify: { $_ };
[download]

See the documentation of classify for more information.

Update: A nicer way to write the first loop is

for @($in) -> $k, $v {
    %h{$k} //= [];
    %h{$k}.push: $v;
}
[download]