in reply to Finding installed program version in Win32 registry

There is a useful technique for dealing with this kind of variably ordered input. It revolves around placing captures inside lookahead assertions.

Because the lookahead assertions do not alter pos, the captured fields are placed into the capture variables ($1, $2, $3 ... ), in the same order, regardless of the order in which that information appears in the input. This is very useful as it greatly simplifies the subsequent processing.

The following example I've re-ordered the two fields of interest in three copies of the sample data, and the output shows that the two fields (DisplayName & DisplayVersion) have been assigned to $1 & $2 respectively, regarless of their relative positioning in the input record.

This demo use "paragraph mode", ($/ = '';) which assumes that the records are separated by one or more blank lines: 

#! perl -sw
use 5.010;
use strict;

$/ = ''; ## Paragraph mode

while( <DATA> ) {
    m[
        (?= ^ .*? DisplayName    \s+ \S+ \s+ ( [^\n]+ ) \n )
        (?= ^ .*? DisplayVersion \s+ \S+ \s+ ( [^\n]+ ) \n )
    ]xsm and say "Name: $1 Version $2";
}

[download]
<Reveal this spoiler or all in this thread>

Output:

c:\test>755675.pl
Name: Adobe Reader 8 Version 8.0.0
Name: Adobe Reader 8 Version 8.0.0
Name: Adobe Reader 8 Version 8.0.0

[download]
Examine what is said, not who speaks -- Silence betokens consent -- Love the truth but pardon error.
"Science is about questioning the status quo. Questioning authority".
In the absence of evidence, opinion is indistinguishable from prejudice.
"Too many [] have been sedated by an oppressive environment of political correctness and risk aversion."

Replies are listed 'Best First'.
Re^2: Finding installed program version in Win32 registry
by 1Nf3 (Pilgrim) on Apr 06, 2009 at 11:46 UTC

    Thank you very much for your answer. This is a really useful technique. Regular expressions will never cease to amaze me.

    This leaves just the question of checking just the required few applications. But I think I'll do it by pushing "Name: $1 Version $2" onto a separate list and then, I'll do something along the lines of: 

    foreach (@cleanlist) {
    if (/Adobe Reader.+Version\s+(.+)/) {
        $gathered_data{'AReaderVer'}=$1;
    }
}

    [download]

    Maybe it's not the best way, but I think it should work. Thank you very much for your help.

    Luke
[reply]
[d/l]
[select]

      Yes, that will work. But you could avoid the post-filtering step by hard coding the application name into the regex: 

      while( <DATA> ) {
    m[
        (?= ^ .*? DisplayName    \s+ \S+ \s+ ( Adobe \s Reader \s 8 ) 
+\n )
        (?= ^ .*? DisplayVersion \s+ \S+ \s+ ( [^\n]+ ) \n )
    ]xsm and say "Name:$1 Version:$2";
}

      [download]

      Now, the same information will be captured, but only when the name matches your requirements. If you want to capture the version information for several different apps but exclude any others, then just put the names of those you want to capture into an alternation: 

      while( <DATA> ) {
    m[
        (?= ^ .*? DisplayName    \s+ \S+ \s+ (
              Adobe \s Reader \s 8
        |     Another \s app \s description
        |     Yet \s Another \s Application
        ) \n )
        (?= ^ .*? DisplayVersion \s+ \S+ \s+ ( [^\n]+ ) \n )
    ]xsm and say "Name:$1 Version:$2";
}

      [download]

      But note: Due to the use of /x on the regex, you will need to explicitly signify any whitespace within the app descriptions using \s (or perhaps \s+).

      Examine what is said, not who speaks -- Silence betokens consent -- Love the truth but pardon error.
      "Science is about questioning the status quo. Questioning authority".
      In the absence of evidence, opinion is indistinguishable from prejudice.
[reply]
[d/l]
[select]

In Section Seekers of Perl Wisdom