Anonymous Monk has asked for the wisdom of the Perl Monks concerning the following question:

I use Perl::Critic and like it, but one thing I do not agree with is that it uses perldoc hardcoded as POD renderer. That's nothing worth to contribute a patch for, it just complicates everything for very little public gain. So I went into the sources (first the perlcritic program, and in recent releases, Perl::Critic::Command) and edited it to use annopod instead, just for myself.

Now I got fed up that every new release overwrites my local changes again, so I just spent some time to do it the proper way, like I should have done in the first place, changing behaviour through polymorphism. Behold pcpod! Instead of writing perlcritic --doc $POLICY_NAME I write pcpod $POLICY_NAME. 

#!/usr/bin/env perl
package Perl::Critic::Command::RenderPolicyDocsAnnopod;
use parent 'Perl::Critic::Command';
sub _render_policy_docs {
    my (%opts) = @_;
    my $pattern = delete $opts{-doc};

    require Perl::Critic;
    $critic = Perl::Critic->new(%opts);
    _set_up_pager($critic->config()->pager());

    require Perl::Critic::PolicyFactory;
    my @site_policies  = Perl::Critic::PolicyFactory->site_policy_name
+s();
    my @matching_policies  = grep { $_ =~ m/$pattern/ixms } @site_poli
+cies;

    exec 'annopod', $matching_policies[0] or die "exec annopod failed:
+ $!\n";
}

unshift @ARGV, '--doc';
Perl::Critic::Command::RenderPolicyDocsAnnopod->run();

[download]

When I said »spent some time«, that was a lie. The code above really just took two minutes or so, but the last half hour I've been knee-deep in the debugger to find out why the stupid thing doesn't work, that is it still is the unoverridden behaviour. Aaaaargh! Relevant excerpt is below. Would the kind monks please deliver explanation and advice? 

> perl -d `which pcpod` CodeLayout::RequireUseUTF8

[...]

DB<1> s
Perl::Critic::Command::_dispatch_special_requests(.../lib/perl5/site_p
+erl/5.10.0/Perl/Critic/Command.pm:139):
139:        if ( $opts{-doc}             ) { _render_policy_docs( %opt
+s ) }  #Exits

DB<1> s
Perl::Critic::Command::_render_policy_docs(.../lib/perl5/site_perl/5.1
+0.0/Perl/Critic/Command.pm:588):
588:        my (%opts) = @_;

[download]

Replies are listed 'Best First'.
Re: why does this subclassing not work?
by Anonymous Monk on Apr 10, 2009 at 09:30 UTC
    It doesn't work because Perl::Critic::Command always calls Perl::Critic::Command::_render_policy_docs, so even Perl::Critic::Command::RenderPolicyDocsAnnopod always calls Perl::Critic::Command::_render_policy_docs.

    You're going to have to override(redefine) Perl::Critic::Command::_render_policy_docs, or convince Perl::Critic::Command author to make subclassing easier ( use $self->_render_policy_docs instead of _render_policy_docs).

[reply]
[d/l]
Re: why does this subclassing not work?
by gone2015 (Deacon) on Apr 10, 2009 at 14:35 UTC

    You could try:

    use Perl::Critic::Command ;

use strict ;
use warnings ;

{ package Perl::Critic::Command ;

  sub _render_policy_docs {
      my (%opts) = @_;
      my $pattern = delete $opts{-doc};

      require Perl::Critic;
      my $critic = Perl::Critic->new(%opts);
      _set_up_pager($critic->config()->pager());

      require Perl::Critic::PolicyFactory;
      my @site_policies  = Perl::Critic::PolicyFactory->site_policy_na
+mes();
      my @matching_policies  = grep { $_ =~ m/$pattern/ixms } @site_po
+licies;

      exec 'annopod', $matching_policies[0] or die "exec annopod faile
+d: $!\n";
  } ;
} ;

unshift @ARGV, '--doc';
Perl::Critic::Command->run();

    [download]
    which does pretty much what you wanted to do by overriding a method -- but by redefining the subroutine...

    With use warnings you'll see it warn you about the redefinition. Of course, if the author changes the _render_policy_docs subroutine you're in a different sort of trouble... so: use at your own risk !

[reply]
[d/l]
[select]

Back to Seekers of Perl Wisdom