vinoth.ree has asked for the wisdom of the Perl Monks concerning the following question: 

use Data::Dumper;
sub Create_arrayref{
 [@_];
};

sub Create_hashref{
    {@_};
};

my $hash_ref=&Create_hashref(1,2,3,4,5,6,7,8,9,'ree');

print Dumper $hash_ref;

my $array_ref=&Create_arrayref(1,2,3,4,5,6,7,8,9,'ree');

print Dumper $array_ref;

[download]

In the above code I tried to create the reference for the array and hash, For array I was getting array reference correctly but, for hash I was getting 10, When I use return like return {@_};it giving hash reference, why it is like that any specific reason ?

Vinoth,G

Replies are listed 'Best First'.
Re: Creating reference to hash and array
by gone2015 (Deacon) on Apr 10, 2009 at 15:00 UTC

    The problem is that:

      sub Create_hashref{
    {@_};
  };

    [download]
    is less than unambiguous... It might look like an anonymous hash constructor to you, but it's actually a BLOCK containing the rather trivial expression @_, whose value is the length of the @_ array. This:
      sub Create_hashref{
    return {@_};
  };

    [download]
    takes a different view. As does:
      sub Create_hashref{
    +{@_};
  };

    [download]

    This is discussed in Making References -- see paragraph 3.

[reply]
[d/l]
[select]

      Fantastic! Thanks

      Vinoth,G
[reply]
Re: Creating reference to hash and array
by Bloodnok (Vicar) on Apr 10, 2009 at 14:49 UTC
    When used without a preceding return, perl interprets {@_}; as a code block and as a list is the only statement in a block called in scalar context, perl returns the number of elements in the list i.e. 10, as expected.

    Thanx to a previous posting from ikegami, I now know that the way to get the desired result is to force perl to treat the braces as an anonymous hash by prefixing with a '+' i.e. 

    sub Create_hashref{
    +{@_};
};

    [download]

    A user level that continues to overstate my experience :-))
[reply]
[d/l]
[select]
      From a personal point of view, I'd strongly suggest using return {@_} rather than +{@_}.

      If I encountered code with that "+" in it, I'd either waste quite some time wondering what it's doing there, or accidentally break the code when updating it! Using "return" is unlikely to confuse anyone.

      Of course, there may be are other circumstances where "+" is the only way to get the desired result. (Can anyone concoct such an example?) In those cases, I'd have to rely on an informative comment next to it. But hey, we're all diligent with our comments aren't we? :-)

      --
      use JAPH;
      print JAPH::asString();

[reply]
[d/l]
[select]
        Indeed, the PBP recommends such practice, but I answered the question as asked.

        A user level that continues to overstate my experience :-))
[reply]
Re: Creating reference to hash and array
by kennethk (Abbot) on Apr 10, 2009 at 14:37 UTC

    On the other hand, if you use the code:

    sub Create_hashref{
    return {@_};
};

    [download]

    you get your expected result. It appears that in the absence of an operator, Perl interprets {} as a block and not an anonymous hash.

[reply]
[d/l]
Re: Creating reference to hash and array
by jethro (Monsignor) on Apr 10, 2009 at 14:35 UTC 
    sub Create_hashref{
 { my $i=1; @_; };
}

    [download]

    Try this, it gives the same result of "10". '{' is also used as block delimiter and when the parser has to guess if it is used as a block delimiter or a hash reference, it might guess wrong.

[reply]
[d/l]
Re: Creating reference to hash and array
by Anonymous Monk on Apr 10, 2009 at 14:36 UTC
[reply]
[d/l]
Re: Creating reference to hash and array
by bichonfrise74 (Vicar) on Apr 10, 2009 at 16:51 UTC
    Maybe you meant something like this? 
    
print Dumper \$hash_ref;

print Dumper \$array_ref;

    [download]
[reply]
[d/l]

Back to Seekers of Perl Wisdom