deadpickle has asked for the wisdom of the Perl Monks concerning the following question:

Here is what I want to do. I have a text file that contains a matrix of integers. This data was extracted from a GIF and now I need to verify that it did that correctly. The data is intended to be used in a FORTRAN program FYI. I would like to load this data into GD and display it but Im not sure how. Any ideas?

Replies are listed 'Best First'.
Re: Using text data in GD(or other)
by moritz (Cardinal) on Apr 21, 2009 at 20:39 UTC
    I've done that in C with Imlib2, which simply offers you an array of 32 bit values (3 x 8 bits for the color channel, and 8 bits for the alpha channel). Painting a pixel is a simple matter of assigning to that array.

    There's a Perl binding for that, Image::Imlib2, which has set_colour and draw_point - that should be all you need.

[reply]
[d/l]
[select]
Re: Using text data in GD(or other)
by BrowserUk (Patriarch) on Apr 21, 2009 at 20:34 UTC
    1. Create a GD true color image of the appropriate size.
    2. Read the data from your file.
    3. use $img->setPixel( $x, $y, $color ); to set the bits.
    4. Save the image to disk in whichever format floats your boat.
    5. Load it into your favourite image viewer to check the results.
    Examine what is said, not who speaks -- Silence betokens consent -- Love the truth but pardon error.
    "Science is about questioning the status quo. Questioning authority".
    In the absence of evidence, opinion is indistinguishable from prejudice.
[reply]
[d/l]
      Here is what I have so far. It causes an gd-jpeg: JPEG library reports unrecoverable error: and crashes perl. Any ideas? 
      #!/usr/bin/perl -w
use strict;
use GD;
use File::Slurp;

my $width = 102;
my $height = 123;
my $truecolor;
my $x;
my $y;

my $image = GD::Image->new([$width,$height],$truecolor);

my $dbz1 = $image->colorAllocate(0,0,0); #-30
my $dbz2 = $image->colorAllocate(204,255,255); #-28
my $dbz3 = $image->colorAllocate(204,153,204); #-25
my $dbz4 = $image->colorAllocate(153,102,153); #-20
my $dbz5 = $image->colorAllocate(102,51,102); #-15
my $dbz6 = $image->colorAllocate(204,204,153); #-10
my $dbz7 = $image->colorAllocate(153,153,102); #-5
my $dbz8 = $image->colorAllocate(102,102,51); #0
my $dbz9 = $image->colorAllocate(102,255,255); #5
my $dbz10 = $image->colorAllocate(51,153,255); #10
my $dbz11 = $image->colorAllocate(0,0,255); #15
my $dbz12 = $image->colorAllocate(0,255,0); #20
my $dbz13 = $image->colorAllocate(0,204,0); #25
my $dbz14 = $image->colorAllocate(0,153,0); #30
my $dbz15 = $image->colorAllocate(255,255,0); #35
my $dbz16 = $image->colorAllocate(255,204,0); #40
my $dbz17 = $image->colorAllocate(255,104,0); #45
my $dbz18 = $image->colorAllocate(255,0,0); #50
my $dbz19 = $image->colorAllocate(204,51,0); #55
my $dbz20 = $image->colorAllocate(153,0,0); #60
my $dbz21 = $image->colorAllocate(255,0,255); #65
my $dbz22 = $image->colorAllocate(153,51,204); #70
my $dbz23 = $image->colorAllocate(255,255,255); #75
my $dbz24 = $image->colorAllocate(255,255,255); #80

print "$dbz1\n";
my @data = read_file('test_image.txt');
print "@data\n";

for($y=1;$y <= $height;$y++){
    for($x=1;$x <= $width;$x++){
        my $pixel = $x*$y-1;
        print "Pixel Value: $data[$pixel]\n";
        if ($data[$pixel] == 0){
            $image->setPixel($x,$y,$dbz1);
        }
        if ($data[$pixel] > 0 and $data[$pixel] <= 10){
            $image->setPixel($x,$y,$dbz5);
        }
        if ($data[$pixel] > 10 and $data[$pixel] <= 20){
            $image->setPixel($x,$y,$dbz10);
        }
        if ($data[$pixel] > 20 and $data[$pixel] <= 30){
            $image->setPixel($x,$y,$dbz15);
        }
    }
}
my $jpeg = $image->jpeg();
open JPEG,'>','test_image.jpg' || die;
print JPEG $jpeg;

#~ my $gif = $image->gif();
#~ open GIF,'>','test_image2.gif' || die;
#~ print GIF $gif;

exit;

      [download]
[reply]
[d/l]
[select]

        There are a few problems with your attempt.

        1. my $image = GD::Image->new([$width,$height],$truecolor);
          • $width & $height are parameters that should be passed directly, not wrapped in an anonymous subroutine.

            In the POD example: $image = GD::Image->new([$width,$height],[$truecolor]), the brackets [] are intended to indicate that the arguments are optional.

          • The parameter $truecolor should be passed as either 0 or 1. You never give the variable any value.
          my $image = GD::Image->new( $width, $height, 1 ); 
        2. for($y=1;$y <= $height;$y++){
    for($x=1;$x <= $width;$x++){

          [download]

          The pixels in an image (as with most arrays in computing) starts from 0. So your loops should run from 0 to width/height -1. You'll also be less likely to make out-by-one errors if you use Perl's counting loops with in-line variable declarations: 

          for my $y ( 0 ..  $height - 1 ){
    for my $x ( 0 .. $width - 1 ){

          [download]
        3. This 2D to 1D array mapping looks very wrong:         my $pixel = $x*$y-1;

          Even using your original 1-based indices, this mapping reuses several indices from the data, and completely omits others. In this example indices 1, 2 & 5 are reused; 4, 6 & 7 are never used: 

          for my $y ( 1 .. 3 ) { 
    for my $x ( 1 .. 3 ) { 
        print "[$x:$y] => ", $x*$y-1; 
    } 
}
[1:1] =>  0
[2:1] =>  1
[3:1] =>  2
[1:2] =>  1
[2:2] =>  3
[3:2] =>  5
[1:3] =>  2
[2:3] =>  5
[3:3] =>  8

          [download]

          Using 0-based indices, you probably want something like: 

                  my $pixel = ( $y * $width ) + $x;

          [download]
        4.         if( $data[ $pixel ] == 0 ){
            $image->setPixel( $x, $y, $dbz1 );
        }
        if( $data[ $pixel ] > 0 and $data[$pixel] <= 10){
            $image->setPixel($x,$y,$dbz5);
        }
        if ($data[$pixel] > 10 and $data[$pixel] <= 20){
            $image->setPixel($x,$y,$dbz10);
        }
        if ($data[$pixel] > 20 and $data[$pixel] <= 30){
            $image->setPixel($x,$y,$dbz15);
        }

          [download]

          Whilst the way you have that coded will work, you are making more work for yourself (having to specify the lower bounds of the if statements), and more work for your program (having to test 7 conditions for every pixel). Better to use an if/elsif cascade: 

                  if( $data[ $pixel ] == 0 ){
            $image->setPixel( $x, $y, $dbz1 );
        }
        elsif( $data[ $pixel ] <= 10 ){
            $image->setPixel( $x, $y, $dbz5 );
        }
        elsif( $data[ $pixel ] <= 20 ){
            $image->setPixel( $x, $y, $dbz10 );
        }
        elsif( $data[ $pixel ] <= 30 ){
            $image->setPixel( $x, $y, $dbz15 );
        }
        else {
            ## What do you want to do if the value is greater than 30?
+?
        }

          [download]

          In this way, the later conditions are only tested if the earlier ones have failed, and because of that, you do not need to test the lower bounds. 

        5. open JPEG,'>','test_image.jpg' || die;
print JPEG $image->jpeg();

          [download]

          Several problems here:

          • Either use parens on your open open( JPEG,'>','test_image.jpg' ) || die; or use the low-precedence or keyword: open JPEG,'>','test_image.jpg' or die;. I favour the latter. See the docs for the reasons.
          • If you are going to die, at least do yourself the favour of printing $! so you know why you died.
          • It's a good idea to binmode files used for binary data. 
            binmode JPEG;

            [download]
          • It's a good idea to explicitly close files:

        Putting that all together you end up with something like: 

        #!/usr/bin/perl -w
use strict;
use GD;
use File::Slurp;

my $width = 102;
my $height = 123;

my $image = GD::Image->new( $width, $height, 1 );

my $dbz1 = $image->colorAllocate(0,0,0); #-30
my $dbz2 = $image->colorAllocate(204,255,255); #-28
my $dbz3 = $image->colorAllocate(204,153,204); #-25
my $dbz4 = $image->colorAllocate(153,102,153); #-20
my $dbz5 = $image->colorAllocate(102,51,102); #-15
my $dbz6 = $image->colorAllocate(204,204,153); #-10
my $dbz7 = $image->colorAllocate(153,153,102); #-5
my $dbz8 = $image->colorAllocate(102,102,51); #0
my $dbz9 = $image->colorAllocate(102,255,255); #5
my $dbz10 = $image->colorAllocate(51,153,255); #10
my $dbz11 = $image->colorAllocate(0,0,255); #15
my $dbz12 = $image->colorAllocate(0,255,0); #20
my $dbz13 = $image->colorAllocate(0,204,0); #25
my $dbz14 = $image->colorAllocate(0,153,0); #30
my $dbz15 = $image->colorAllocate(255,255,0); #35
my $dbz16 = $image->colorAllocate(255,204,0); #40
my $dbz17 = $image->colorAllocate(255,104,0); #45
my $dbz18 = $image->colorAllocate(255,0,0); #50
my $dbz19 = $image->colorAllocate(204,51,0); #55
my $dbz20 = $image->colorAllocate(153,0,0); #60
my $dbz21 = $image->colorAllocate(255,0,255); #65
my $dbz22 = $image->colorAllocate(153,51,204); #70
my $dbz23 = $image->colorAllocate(255,255,255); #75
my $dbz24 = $image->colorAllocate(255,255,255); #80

print "$dbz1\n";
my @data = read_file('test_image.txt');
print "@data\n";

for my $y ( 0 ..  $height - 1 ){
    for my $x ( 0 .. $width - 1 ){
        my $pixel = ( $y * $width ) + $x;
#        print "Pixel Value: $data[$pixel]\n";
        if( $data[ $pixel ] == 0 ){
            $image->setPixel( $x, $y, $dbz1 );
        }
        elsif( $data[ $pixel ] <= 10 ){
            $image->setPixel( $x, $y, $dbz5 );
        }
        elsif( $data[ $pixel ] <= 20 ){
            $image->setPixel( $x, $y, $dbz10 );
        }
        elsif( $data[ $pixel ] <= 30 ){
            $image->setPixel( $x, $y, $dbz15 );
        }
        else {
            ## What do you want to do if the value is greater than 30?
+?
        }
    }
}

open JPEG,'>','test_image.jpg' or die $!;
binmode( JPEG );
print JPEG $image->jpeg();
close JPEG;
exit;

        [download]

        Which may not produce exactly what you are after, but will run and should get a step forward.

        Examine what is said, not who speaks -- Silence betokens consent -- Love the truth but pardon error.
        "Science is about questioning the status quo. Questioning authority".
        In the absence of evidence, opinion is indistinguishable from prejudice.
[reply]
[d/l]
[select]
        You're already using File::Slurp, so 
        write_file( 'test_image.jpg', {binmode => ':raw' }, $image->jpeg) ;
write_file( 'test_image2.gif', {binmode => ':raw' }, $image->gif) ;

        [download]
[reply]
[d/l]

Back to Seekers of Perl Wisdom