[ We'll both have an easier time if you use <c>...</c> around your code. ]

The key to repeating the same action for multiple inputs is to store the inputs in a hash or array, not 12 variables.

use strict;
use warnings;

sub compare_arrays {
   my ($array1, $array2) = @_;

   return 0 if @$array1 != @$array2;
   
   for my $i (0..$#$array1) {
      return 0 if $array1->[$i] ne $array2->[$i];
   }
   
   return 1;
}


my %lists = (
   D => [ 0, 1, 2, 3, 4, 5, 6, 7, 8, 9                            ],
   E => [qq( a b c d e f g h i j k l m n o p q r s t u v w x y z )],
   F => [ 1, 3, 5, 7, 9                                           ],
   G => [qq( a b c d e f g h i j k l m                           )],
   H => [ 2, 4, 6, 8                                              ],
   K => [qq( n o p q r s t u v w x y z                           )],
   M => [ 0, 1, 2, 3, 4, 5, 6, 7, 8, 9                            ],
   P => [qq( a b c d e f g h i j k l m n o p q r s t u v w x y z )],
   S => [ 1, 3, 5, 7, 9                                           ],
   T => [qq( a b c d e f g h i j k l m                           )],
   X => [ 2, 4, 6, 8                                              ],
   Z => [qq( n o p q r s t u v w x y z                           )],
);

my @keys = keys %lists;

for my $i1 (0..$#keys) {
   my $key1 = $keys[$i1];

   for my $i2 ($i1+1..$#keys) {
      my $key2 = $keys[$i2];
      if ( compare_arrays($lists{$key1}, $lists{$key2}) ) {
         print("$key1 is identical to $key2\n");
      } else {
         #print("$key1 is different than $key2\n");
      }
   }
}
[download]

S is identical to F
T is identical to G
X is identical to H
P is identical to E
K is identical to Z
M is identical to D
[download]

The reason for using

my @keys = keys %lists;

for my $i1 (0..$#keys) {
   my $key1 = $keys[$i1];

   for my $i2 ($i1+1..$#keys) {
      my $key2 = $keys[$i2];
[download]

instead of

for my $key1 (keys %lists) {
   for my $key2 (keys %lists) {
[download]

is to avoid useless duplication of outputs.

I appreciate you help. I will take your advice and work on this.

This is a FAQ. See perlfaq4 about How do I test whether two arrays or hashes are equal?, which, coincidentially, is quite similar in structure to what you already have.

Maybe you want to tell us where your problem is?

I'm beginning and unsure of where my problem is. I just figured I'd spend the day working on some code in an ongoing attempt to try to learn it. I thank you for your help and will check out FAQ 4

Your "check_same" sub is written to use just two array refs as args, but you are calling it with a long list of arrays (not refs to arrays). The two calls you have to check_same should look like this:

print "\@D is not the same as \@E\n" unless check_same( \@D, \@E );
print "\@D is the same as \@F\n" if check_same( \@D, \@F );
[download]

sub check_same {
    my ( $ref1, $ref2 ) = @_;
    die "Bad args passed to check_array\n"
        unless ( ref( $ref1 ) eq 'ARRAY' and ref( $ref2 ) eq 'ARRAY' )
+;

    return 0 if @$ref1 != @$ref2;
    for my $i ( 0 .. $#$ref1 ) {
        return 0 if $$ref1[$i] ne $$ref2[$i];
    }
    return 1;
}
[download]

Thank you so much for your help. I will work on this and see how it goes