This is a FAQ. See perlfaq4 or perldoc -q sort:

Found in /usr/local/lib/perl5/5.10.0/pod/perlfaq4.pod
How do I sort an array by (anything)?

If you need to sort on several fields, the following paradigm is useful.

@sorted = sort {
    field1($a) <=> field1($b) ||
    field2($a) cmp field2($b) ||
    field3($a) cmp field3($b)
    } @data;
[download]

Change that to use references and you're done.

While this complicated sort function does work, if there is a lot of data, it is faster to precompute a sort key for each row, and sort using that. The Schwartzian Transform is the standard name for this, and you should read up on it. It is also in perlfaq4.

The general form of the ST is

@sorted = map  { $_->[0] }
          sort { $a->[1] cmp $b->[1] }
          map  { [$_, foo($_)] }
               @unsorted;
[download]

where foo() does whatever is necessary to make a sortable key. Obviously it is very specific to the data that you are working with. In your case the second column is an integer, and the fourth is either a 0 or a 1, so I'd go with something like

sub foo($) { $_[0]->[1] . "." . $_[0]->[3]; }
[download]

which will produce a single real number that you can compare using the <=> operator.

use strict;
use warnings;

my @megaMotif = (
    [ "AGCT", "0", "370", "1" ],
    [ "AGGT", "3", "52",  "1" ],
    [ "TGAA", "2", "233", "0" ],
    [ "AGAG", "0", "32",  "0" ]
);

my @megaMotifSorted =
    sort { $a->[1] <=> $b->[1] || $a->[3] <=> $b->[3] }
    @megaMotif;
[download]

1. The name of the language is "Perl", not "PERL".
2. When making your array, the outhernmost brackets should be parentheses "( ... )" and not square brackets "[ ... ]". Square brackets will make your list into an anonymous array rather than a normal array. In your version @megaMotif only contains one element, such as "ARRAY(some_hex_value)". Doing a sort on an array with only one element will not bring you very far.

   Did you just change the brackets in your posting or am I going mad? I could have sworn I just copied-and-pasted your code in my editor and the outernmost brackets were square and not round. If you did change them afterwards, make a little note of it otherwise it gets difficult to follow the discussion.

Thank You.
Sometimes I get stuck badly and dont see the easiest thing by which I could move ahead like this. A little push in the right direction is invaluable.
Happens with anyone else?
Thank You again!

Sure does! Happens a lot to me. Here are some links to posts to remind you that you are in good company - the best really:
• Stupid mistakes I repeatedly make - thread started by brian_d_foy, author of one of the more popular Perl programming books.
• Avoiding silly programming mistakes - various practical tips on how to avoid unnecessary silly mistakes - including - "get a good nights sleep".
• And there are any number of nodes posted by senior monks solely to get a second set of eyes for the mistakes they can't see. To find them, try a google site search for "obvious mistake". I know of at least one of these that made it to the Best node of the day.

Posting questions, even ones that turn out to be silly mistakes can be very, very helpful to the next person down the road who makes the same silly mistake. Perl Monks is the great place it is because people have had the courage to make mistakes and let others see them.

Best, beth

AGCT 0 370 1
AGAG 0 32 0
TGAA 2 233 0
AGGT 3 52 1
[download]

use strict;        # before anything else
use Sort::Fields;  
use Data::Dumper;

open(INP,"data.txt") || die "where's the file eh?";
my @data=<INP>;

chomp (@data); # remove new line characters

print "before sorting...\n";
print Dumper @data;  

#sort the data on the 2nd and the 4th field
#this is numeric sort, as indicated by the "n"

my @sorted = fieldsort '\t', [ '2n', '4n' ], @data;  

print "after sorting...\n";
print Dumper @sorted;
[download]

before sorting...
$VAR1 = 'AGCT    0    370    1';
$VAR2 = 'AGAG    0    32    0';
$VAR3 = 'TGAA    2    233    0';
$VAR4 = 'AGGT    3    52    1';
after sorting...
$VAR1 = 'AGAG    0    32    0';
$VAR2 = 'AGCT    0    370    1';
$VAR3 = 'TGAA    2    233    0';
$VAR4 = 'AGGT    3    52    1';
[download]

perliff

Note that the loop
    foreach my $ele (@data) {chomp $ele}
is the same as the statement
    chomp(@data);

thanks for the tip! saves me a lot of typing. I changed the code.

perliff

----------------------

"with perl on my side"

$ cat junk.txt
AGCT:0:370:1
AGGT:3:52:1
TGAA:2:233:0
AGAG:0:32:0
$ sort -t: -k2,3 junk.txt
AGAG:0:32:0
AGCT:0:370:1
TGAA:2:233:0
AGGT:3:52:1
[download]

Hello,
I forgot to mention I am coding this thing in PERL. I wish to have a 2D array of all those values so that I may process the array further.
I believe to do it in the elegant way you suggested, I would have to output that array in a file first- say junk.txt
"System" command would help me with the "sort" command.
I will again have to retrieve the sorted file and slurp it in an array once more.
I really do not wish to have that overhead but if most would agree that this is the easiest way to go about it I would go ahead and use it.

Code it in Perl then ...

#!/usr/bin/perl -w
use strict;
my @mega = (
                  ["AGCT", "0", "370",  "1"],
                  ["AGGT", "3", "52",   "1"],
                  ["TGAA", "2", "233",  "0"],
                  ["AGAG", "0", "32",   "0"]
                );

open ( fh, ">junk.txt" );
for my $row (@mega) {
        print fh (join ":", @{$row}) . "\n";
}
close fh;
my $shellout = <<`SHELL`;
sort -n -t: -k2,4 junk.txt
SHELL
print "$shellout\n";
[download]

... if you expend some effort you can find away of avoiding writing the array to a file as sort does accept input form STDIN also, read the man page.