my $str = '\u00E1\u015F';
$str =~ s/\\u([0-9a-fA-F]{4,6})/chr(hex($1))/eg;
open my $handle, '>:encoding(UTF-8)', $file
    or die "Can't open file `$file' for writing: $!";
print $handle $str;
close $handle or warn $!;
[download]

See also Character encodings and Unicode in Perl.

$str =~ s/\\u([0-9a-fA-F]{4,6})/chr(hex($1))/eg;

It looks like Java unicode escapes. These always have exactly 4 digits as far as I've seen. \u20AC80 would mean €80, but your example would not see it that way :)

s/\\u([0-9A-Fa-f]{4})/chr hex $1/ge;

    or die "Can't open file `$file' for writing: $!";
[download]

Backticks and apostrophes as balanced quotes are ugly, and not at all balanced, in just about any font.

Actually you can change the code page to utf8 for cmd.exe (for $^O >= win2k):

system(chcp => 65001, '2>nul', '1>nul')
[download]

But you'll also need a font to display the chars :) Lucida Console can't display everything AFAIK. However, it'll be enough for your local code page. It's good enough for Turkish for example.

But you'll also need a font to display the chars :) Lucida Console can't display everything AFAIK.

No font contains every glyph that Unicode supports. That's why good software supports falling back to other fonts; cmd.exe is not good software in this regard :)

Your system call is wrong. You're telling Perl to pass '2>nul' and '1>nul' as parameters to chcp while they only make sense in a command passed to the shell. The call should be

system('chcp 65001 2>nul 1>nul')
[download]

which is short for

system(cmd => ( '/c' => 'chcp 65001 2>nul 1>nul' ) )
[download]

If you want to avoid calling the shell, you need the following:

open(my $fh, '>', 'nul') or die "open nul: $!\n";
my $pid = open3(
    undef,             # Use parent's STDIN
    '>&'.fileno($fh),  # STDOUT = nul
    undef,             # STDERR = STDOUT
    chcp => 65001,
);
waitpid($pid, 0);
[download]

Now, system is buggy on Windows, so your code might actually function as you intend it to. But if it does, you're relying on a bug in Perl.