Re: How can I group lines in a file?

zwon has pointed you in the right direction but I note that your output is not sorted by name but retains the order in which names first occured in the data. To keep that order you will need to preserve it in the hash and sort on it when printing.

use strict;
use warnings;

my $order = 0;
my %names = ();
while( <DATA> )
{
    my( $name, $value ) = split;
    $names{ $name }->{ order } = ++ $order
       unless exists $names{ $name };
    push @{ $names{ $name }->{ values } }, $value;
}

print do
   {
       local $" = q{,};
       qq{$_ @{ $names{ $_ }->{ values } }\n};
   }
   for sort
       {
           $names{ $a }->{ order } <=> $names{ $b }->{ order }
       }
       keys %names;

__END__
jim  14
john 23
ernest 38
matilda 43
jim 34
ernest 27
john 44
matilda 22
[download]

The output.

jim 14,34
john 23,44
ernest 38,27
matilda 43,22
[download]

I hope this is of interest.

Cheers,

JohnGG

Comment on Re: How can I group lines in a file? Select or Download Code

Replies are listed 'Best First'.
Re^2: How can I group lines in a file? by zwon (Abbot) on May 17, 2009 at 07:45 UTC
Just want to note that you can get the same order if you sort by name length or by first value ;) `use strict; use warnings; my %res; while (<DATA>) { my ( $name, $weight ) = split /\s+/; push @{ $res{$name} }, $weight; } for ( sort { length($a) cmp length($b) } keys %res ) { print "$_ ", join( ",", @{ $res{$_} } ), "\n"; } for ( sort { $res{$a}->[0] <=> $res{$b}->[0] } keys %res ) { print "$_ ", join( ",", @{ $res{$_} } ), "\n"; } __DATA__ jim 14 john 23 ernest 38 matilda 43 jim 34 ernest 27 john 44 matilda 22` [download]	[reply] [d/l]

Replies are listed 'Best First'.

Re^2: How can I group lines in a file?
by zwon (Abbot) on May 17, 2009 at 07:45 UTC

Just want to note that you can get the same order if you sort by name length or by first value ;)

use strict;
use warnings;

my %res;
while (<DATA>) {
    my ( $name, $weight ) = split /\s+/;
    push @{ $res{$name} }, $weight;
}
for ( sort { length($a) cmp length($b) } keys %res ) {
    print "$_ ", join( ",", @{ $res{$_} } ), "\n";
}
for ( sort { $res{$a}->[0] <=> $res{$b}->[0] } keys %res ) {
    print "$_ ", join( ",", @{ $res{$_} } ), "\n";
}

__DATA__
jim  14
john 23
ernest 38
matilda 43
jim 34
ernest 27
john 44
matilda 22
[download]

[reply]
[d/l]