in reply to num keys of the hash within hash?

There are two possibilities here, and without seeing your code I can only guess.

Using a hash in scalar context returns "x/y", where x is the number of values and y is the number of allocated buckets (see Scalar values). If you have warnings on, using that in numeric context will warn you that something that wasn't a number was used as one. Of course, since the leading number is exactly what you want, the numification is actually successful even though the interpreter spits a warning. You can fix this by using keys or values in scalar context instead or suppressing the warning locally.

The other possibility is that you are passing a reference when you intend to be passing a hash (a hash or hashes is really a hash of hash references). See perlref and/or perlreftut for information on dereferencing.

Replies are listed 'Best First'.
Re^2: num keys of the hash within hash?
by AnomalousMonk (Archbishop) on May 26, 2009 at 17:40 UTC
    ... since the leading number is exactly what you want, the numification is actually successful ...
    However, the leading number may not be quite what is wanted.

    Consider the following example: 

    >perl -wMstrict -le
"my %hash = (
   one => { fee => 33,  fie => 44,            },
   two => { foo =>  2,  bar =>  3,  baz => 4, },
   );
 my $k_n = keys %{ $hash{one} };
 my $k_s = '' . %{ $hash{one} };
 print $k_n;
 print $k_s, '  <--';
 print scalar keys %{ $hash{two} };
 print        '' . %{ $hash{two} };
"
2
1/8  <--
3
3/8

>perl -wMstrict -le
"my %hash = (
   one => { fee => 33,  xyz => 44,            },
   two => { foo =>  2,  bar =>  3,  baz => 4, },
   );
 my $k_n = keys %{ $hash{one} };
 my $k_s = '' . %{ $hash{one} };
 print $k_n;
 print $k_s, '  <--';
 print scalar keys %{ $hash{two} };
 print        '' . %{ $hash{two} };
"
2
2/8  <--
3
3/8

    [download]
    In the both cases, the evaluation of  scalar keys %{ $hash{one} } (or of  keys %{ $hash{one} in a scalar context) is (and always will be) the same: 2.

    However, the first digit of the stringization of  '' . %{ $hash{one} } is not the same in both cases. There has been an unfortunate collision in  one => { fee => 33, fie => 44 } and both 'fee' and 'fie' occupy the same bucket of the 8 allocated for this (anonymous) (sub-)hash. With  one => { fee => 33, xyz => 44 }, this tragedy has been avoided and the two keys occupy two separate buckets.

    Moral: As recommended by kennethk, always use the scalar evaluation of keys, not the stringization of the hash which, while interesting, may be misleading. And please don't suppress warnings without good reason.

    Update: Here's a much more concise example. The details of the discussion above don't quite apply any more, but you get the picture. 

    >perl -wMstrict -le
"my %ha = ( fee => 33,  fie => 44, );
 my %hb = ( fee => 33,  xyz => 44, );
 printf qq{keys (%s): %ld   %s \n},
        join(' ', sort keys %$_),
        scalar keys %$_,
        'buckets used/allocated: ' . %$_,
        for \(%ha, %hb);
"
keys (fee fie): 2   buckets used/allocated: 1/8
keys (fee xyz): 2   buckets used/allocated: 2/8

    [download]
[reply]
[d/l]
[select]

In Section Seekers of Perl Wisdom