You can have an array of hash refs instead.

@clients = (
    { MAC => $mac, RSSI => $rssi, SNR => $snr }, /* 0 */
    { MAC => $secondmac, RSSI => $secondrssi, SNR => $secondsnr }, /* 
+1 */
    /* etc */
);
[download]

Then you can grab the bits like

%client_0 = %{$clients[0]};
[download]

etc.

To build it on the fly, you'd have code like:

my @clients;

# The whole hash at once
$clients[0] = { MAC => $mac, /* ... */ };

# Or setting individual bits
$clients[0]->{MAC} = $mac;
[download]

This is pretty well covered in the documentation, such as in perlreftut and perldsc.

fullermd -

My issue here is with creating the array and populating it not knowing how many clients I'll have at any one time. So I guess what I'll have to do is output the command to show the currently connected clients to a text file and parse the text file until I reach EOF. Since the file contains words and information other than MAC addresses, I'll know that when I regex match a MAC address, that will be a line to parse and add to the array. Again, I do this until I reach EOF.

Thanks!!

Of course, if you're always looking up data by MAC, it could make more sense to structure it as a giant hash, keyed by the MAC, of hash (refs) of the data. That would make looking up particular MAC's faster and a bit cleaner. It may be easier to read too, depending on your own preferences.

#!/usr/bin/env perl5
use strict;
use warnings;

my %clients;
my $curmac;

while(<DATA>)
{
    chomp;

    # Assume a format of "Type Data"
    my ($type, $data) = split / /;

    # If it's a MAC address, assume later lines refer to this MAC
    if($type eq "MAC")
    {
        $curmac = $data;
        next;
    }

    # RSSI and SNR just get saved
    $clients{$curmac}{RSSI} = $data if $type eq "RSSI";
    $clients{$curmac}{SNR} = $data  if $type eq "SNR";
}

# Show it
use Data::Dumper; print Dumper \%clients;

# Find a given entry
sub showmacsnr
{
    my $mac = shift;
    my $ent = $clients{$mac};

    if($ent)
    {
        print "MAC $mac has SNR $ent->{SNR}\n";
    }
    else
    {
        print "Can't find MAC $mac\n";
    }
}

showmacsnr("ba:98:76:54:32:10");
showmacsnr("thi:is:is:nt:re:al");


# Sample data
__DATA__
MAC 01:23:45:67:89:ab
RSSI 12
SNR 18
MAC ba:98:76:54:32:10
RSSI 7
SNR 3
[download]

% ./tst.pl
$VAR1 = {
          'ba:98:76:54:32:10' => {
                                   'SNR' => '3',
                                   'RSSI' => '7'
                                 },
          '01:23:45:67:89:ab' => {
                                   'SNR' => '18',
                                   'RSSI' => '12'
                                 }
        };
MAC ba:98:76:54:32:10 has SNR 3
Can't find MAC thi:is:is:nt:re:al
[download]

Right, but you don't have to presize it. Just push entries onto it as you parse them.

For instance, to invent a stupid-simple data format, and demonstrate parsing it and doing a thing or two with the data once parsed:

#!/usr/bin/env perl5
use strict;
use warnings;

my @clients;
my %tmp;

while(<DATA>)
{
    chomp;

    # Assume a format of "Type Data"
    my ($type, $data) = split / /;

    # If it's a MAC address, save off our pre-existing record (if any)
+,
    # and start a new one.
    if($type eq "MAC")
    {
        if(keys %tmp)
        {
            # Have to unroll a copy here, otherwise the next line empt
+ies
            # it out.
            push @clients, { (%tmp) };
            %tmp = ();
        }

        $tmp{MAC} = $data;
    }

    # RSSI and SNR just get saved
    $tmp{RSSI} = $data if $type eq "RSSI";
    $tmp{SNR} = $data  if $type eq "SNR";
}

# Save the 'last' one if we fell off the end
push @clients, \%tmp if keys %tmp;

# Show it
use Data::Dumper; print Dumper \@clients;

# Find a given entry
sub showmacsnr
{
    my $mac = shift;
    my @ba = grep { $_->{MAC} eq $mac } @clients;

    if(@ba)
    {
        my $ent = $ba[0];
        print "MAC $mac has SNR $ent->{SNR}\n";
    }
    else
    {
        print "Can't find MAC $mac\n";
    }
}

showmacsnr("ba:98:76:54:32:10");
showmacsnr("thi:is:is:nt:re:al");


# Sample data
__DATA__
MAC 01:23:45:67:89:ab
RSSI 12
SNR 18
MAC ba:98:76:54:32:10
RSSI 7
SNR 3
[download]

So you end up with output like:

% ./tst.pl 
$VAR1 = [
          {
            'RSSI' => '12',
            'SNR' => '18',
            'MAC' => '01:23:45:67:89:ab'
          },
          {
            'SNR' => '3',
            'RSSI' => '7',
            'MAC' => 'ba:98:76:54:32:10'
          }
        ];
MAC ba:98:76:54:32:10 has SNR 3
Can't find MAC thi:is:is:nt:re:al
[download]

my @clients;
$clients[0] = {"MAC"=>$mac,"RSSI"=>$rssi,"SNR"=>$snr};
...
[download]