You're mistaken as hashes are (by nature) unsorted. You may very well have a sorted list of keys in which case you can use a slice (my @first_five = @sorted_keys[0..4]).

First of all, I don't know what you mean by "sorted". A hash is not going to be sorted unless it's tied, like Tie::IxHash.

What you are trying to do is fairly easy. What have you tried so far? We'd love to put in the effort to help you if you would be willing to put in some effort.

To get you started, I would approach this with the following steps:

1. Put sorted keys into @keys
2. Loop over the first five elements of @keys (many ways to achieve th
+is)
3. Print those five records in the loop: print $hash{$key}
[download]

for my $i ( 0 .. 4 ) {
   my $key = $sorted_keys[$i];
   print "$hash{$key}\n";
}
[download]

or

for my $key ( @sorted_keys[ 0 .. 4 ] ) {
   print "$hash{$key}\n";
}
[download]

or

my @values = @hash{ @sorted_keys[ 0 .. 4 ] };
[download]

#!/usr/bin/perl

use strict;

my %hash = ( 'a' => '1', 'b' => '2', 'c' => '3',
             'f' => '6', 'e' => '5', 'd' => '4' );
my $count = 0;

foreach my $i ( sort keys %hash ) {
    print "$i ==> $hash{$i}\n" if ($count <= 4);
    $count++;
}
[download]

This is good, but since (sort keys %hash) is a list, we can just take a list slice:

my %hash = ( 'b' => '2', 'a' => '1', 'c' => '3',
             'f' => '6', 'e' => '5', 'd' => '4' );

foreach my $key ( (sort keys %hash)[0..4] ) 
{
    print "$key ==> $hash{$key}\n" 
}
#prints..
#a ==> 1
#b ==> 2
#c ==> 3
#d ==> 4
#e ==> 5
[download]

Hash will not be sorted by itself. Do sort based on key and take top 5 elements and print the hash.

use strict;
use warnings;
my %hash=(key6=>'value6',key2=>'value2',key1=>'value1',key3=>'value3',
+key4=>'value4',key5=>'value5');
my @arr=sort keys %hash;
print map{$_.'=>'.$hash{$_}."\n"}@arr[0..4];
[download]