You are using symbolic references, which cannot point to lexical (my) variables. (use strict would have told you that.)

In general, this is a path to much pain. You would (usually) be better off using a hash. (There are a very few cases where the symbolic references might be a better choice, but the odds of this being one of them is really slim.

my %greeting;
my @names = ('peter', 'jonah', 'larry');

foreach my $n (@names) {
   $greeting{$n} = "i like $n";
}

print "$greeting{peter} \n $greeting{jonah} \n $greeting{larry} \n";
[download]

Of course, there's always more than one way.

my %greeting = map { $_ => "i like $_" }
               ('peter', 'jonah', 'larry');

print join( " \n ", @greeting{qw/peter jonah larry/} ),
      " \n";
[download]

(use strict would have told you that.)

Well, use strict wouldn't let you use symbolic references at all. Even if you declared @names, $jonah, $peter, and $larry. Though I guess if you only enable strict for vars, not refs, that might tell you something.

use strict;
use warnings;

my @names = ('peter','jonah','larry');
my %name_hash = ();
foreach (@names) {
    $name_hash{$_} = "i like $_";
}

print "$name_hash{$_}\n" foreach @names;
[download]

In a side note, while you cannot use my on globals, you can localize their values with local. <-- not really relevant.

Update: A useful link, as pointed out by bart in CB: http://www.google.com/search?q=varvarname&btnI=I;

If you are tied to the idea of symbolic refs, you can use them with some degree of stricture with

use strict;
use warnings;

my @names = ('peter','jonah','larry'); 
our ($peter,$jonah,$larry);

foreach (@names) {
    no strict 'refs';
    $$_ = "i like $_";
}

print "$peter\n$jonah\n$larry\n";
[download]

But read the link first.

• Strict and warnings (as my predecessors have)
• qw() for lists (when applicable)
• for in place of foreach

• A variable with for to avoid clobbering $_

for doesn't clobber $_

$ perl -le'$_="abc"; print for "def";  print'
def
abc
[download]