Named subs capture at compile-time, which is problematic for nested subs. Anon subs capture at run-time.

Furthermore, there's no advantage to nesting named subs. They can be called from anywhere just as if they weren't nested.

What follows demonstrates the above points.

Named:

use strict;
use warnings;

sub outer {
   my ($x) = @_;

   sub inner { # XXX bad
      print("$x\n");
   }

   inner();
}

outer(4);
outer(5);
inner();
[download]

Variable "$x" will not stay shared at a.pl line 8.
4
4    # XXX Want 5.
4    # XXX Don't want inner sub to be public
[download]

Anon:

use strict;
use warnings;

sub outer {
   my ($x) = @_;

   local *inner = sub {
      print("$x\n");
   };

   inner();
}

outer(4);
outer(5);
inner();
[download]

4
5
Undefined subroutine &main::inner called at a.pl line 16.
[download]

Note that inner isn't totally private in the last example. It can be done, but what I posted is a good compromise of privacy and code clarity.

Update: Initially forgot to mention the useless nesting of named subs. Added.

Because It doesn't work at all well. Scope of subroutines with same name