So mainarr will be having three arrays.

No:

use strict;
use Data::Dumper;

my @mainarr;
my @arr1=qw(a b c d e);
my @arr2=qw(f g h i j);
my @arr3=qw(k l m n o);
push(@mainarr,@arr1);
push(@mainarr,@arr2);
push(@mainarr,@arr3);

print Dumper \@arr1;
print Dumper \@arr2;
print Dumper \@arr3;
print "-- mainarr\n";
print Dumper \@mainarr;
[download]

If you want to keep the structure of @arr1 etc., you will have to store references to the arrays in @mainarr:

...

push(@mainarr,\@arr1);
push(@mainarr,\@arr2);
push(@mainarr,\@arr3);

print Dumper \@mainarr;
[download]

Then you can get at the values in @arr2 via $mainarr->[1]. Also see References Quick Reference.

Push just adds the values in the second array to the end of the first array. What you have is a flattened list rather than an array of arrays.

If you want to add a reference to an array you need to push(@mainarr,\@arr1);
Then you can access the second element of each using

for $array_ref (@mainarr){
   print "$array_ref->[1]\n";
}
[download]

For further info have a look at perldoc perllol

We cant separate as what you have asked. Since, it has been given in the perldoc for push that, this function is just appending a list to an array.

But, it is possible to push a reference to the array and get back a particular list of elements. like below.,

push @mainarr,\@arr1;

print Dumper @mainarr->[1];
[download]

...sorry for the repetition.

There's no need to be sorry. I like to see a few versions of a solution. I often pick up handy techniques comparing different approaches.

A minor nit though, your snippet won't compile throws a warning under strict and warnings. This is a bit better.

#!/usr/bin/perl

use warnings;
use strict;
use Data::Dumper;

my @arr1 = qw{one two three};
my @arr2 = qw{four five six};
my @mainarr;
push @mainarr, \@arr1, \@arr2;

#print Dumper @mainarr->[1]; # <- line 12

#Using an array as a reference is deprecated at C:\perm\monk.pl line 1
+2.
#C:\perm\monk.pl syntax OK

print Dumper $mainarr[1];

__DATA__
$VAR1 = [
  'four',
  'five',
  'six'
];
[download]

My motto: "Test it _before_ you post it." :-)

update: it does compile ("syntax OK") but it throws a warning

Instead of pushing the array as list context, I you push the reference of each array you can take the @arr2 separately easily

use strict;
use warnings;

use Data::Dumper;

my @mainarr;
my @arr1=qw(a b c d e);
my @arr2=qw(f g h i j);
my @arr3=qw(k l m n o);
push(@mainarr,\@arr1);
push(@mainarr,\@arr2);
push(@mainarr,\@arr3);

# print Dumper \@mainarr;

my $index=0;
foreach (@mainarr){
    print @{$mainarr[$index]} if $index == 1;
    $index+=1;
}
[download]

or, instead of a loop over all of @mainarr, you might use:

print @{$mainarr[1]};
[download]

using foreach?

Yes, We can directly access the array element as you said, but Anonymous Monk asked in foreach thats why I used foreach here.

Vinoth,G

There are some folks who like to call @thingie an array, and folks who like to call @thingie a list. I figure there are some valid arguments on both sides, but that is not the point below..

#!/usr/bin/perl -w
use strict;

my @mainarr;
my @arr1=qw(a b c d e);
my @arr2=qw(f g h i j);
my @arr3=qw(k l m n o);
push(@mainarr,@arr1);
push(@mainarr,@arr2);
push(@mainarr,@arr3);

# you have flattened each list into a single list
# The "push" is similar to a queue operation
# that adds things to the end of the queue.
# there are 4 Perl ops that you should read more
# about (push,pop,shift,unshift), all of these operate
# on lists. 

print "@mainarr\n"; 
# that prints: a b c d e f g h i j k l m n o

print join(" ",@mainarr[5..9]),"\n";
# this is a list slice and prints the 6th-10th things...
# this prints: f g h i j

#If you want to maintain the integrity of these things
#that you "push" onto @mainarr, then they have to be
#grouped together. The way to do that is with a 
#reference to a list. This creates a LoL, a List of List.

push(@mainarr,[@arr1]);
push(@mainarr,[@arr2]);
push(@mainarr,[@arr3]);

print "@mainarr\n"; 
#will produce something like:
#ARRAY(0x182a64c) ARRAY(0x183642c) ARRAY(0x183649c)

foreach $list_ref (@mainarr)
{
   print "@$list_ref\n";
}

#this prints:
#a b c d e
#f g h i j
#k l m n o
[download]

#!/usr/bin/perl

use strict;

my @mainarr;
my @arr1=qw(a b c d e);
my @arr2=qw(f g h i j);
my @arr3=qw(k l m n o);

push (@mainarr, [@arr1], [@arr2], [@arr3]);
print @{$mainarr[1]};
[download]