-- Randal L. Schwartz, Perl hacker

• In C, a common beginner error is to return the address of an automatic variable which is deallocated when the function exits. The perl code above 'feels' roughly equivalent to this, presumably hence the question.
• In perl, as Randal says, variables are reference counted. This is a cool system which means that perl keeps track of whether anything cares about your data and frees it when nothing wants it any more.

  
  sub another_func {
    my $ref = CreateRef();
    # do things with $ref
    return 1;
    # $ref goes out of scope here and so we lose our last
    # reference to the hash and it is freed.
  }
  
  sub CreateRef {
    my %some_hash = ('foo' => 'bar');
    return \%some_hash;
    # We lose the 'some_hash' name reference to
    # the 'some_hash' data, but we have created another
    # reference (the return value) so the data lives...
  }
  [download]

• In perl you can have references to anonymous arrays and hashes. To C coders, this 'feels' like memory allocation, but to perl it doesn't really make any difference to how your memory is freed. (It just means that the data doesn't have a reference to it by virtue of having a name).

  # Note use of {} (same as for accessing hash elem)
  my $ref_to_anon_hash = { foo => 'bar' };
  # Note use of () (same as for accessing array elem)
  my $ref_to_anon_array = [ 1, 2 ];
  [download]

• Reference counting (as used in perl) has one weakness though. It does not take account of loops of references. In this case, you will have a memory leak.

  sub leak_mem {
    my $foo;  # foo data has one reference, the 'foo' name
    my $bar;  # bar data has one reference, the 'bar' name
    $foo = \$bar;  # bar data has two refs
    $bar = \$foo;  # foo data has two refs
    return 1;
    # Oops. foo and bar data reference count are both
    # decremented by one (because the foo and bar names have
    # just gone out of scope), but that doesn't take them
    # to zero.
    # We just lost some bytes, sir.
  }
  [download]

Thank you jbert, that was an excellent reply. It helped me greatly. I hope rchiav was satisfied with the answear.

-= Ozzy =-

can anyone share with me the rules about when data becomes "freed"?

--
Mark Dominus
Perl Paraphernalia