Easier to find all the 10 or more digit numbers, then drop out the special case:

use strict;
use warnings;

my $str = '2222222222 1234567890 0000000000 48192049281924 99999999999
+999';
my @matched = grep {! /^(\d)\1{9,}$/} $str =~ /\b(\d{10,})\b/g;

print "@matched";
[download]

Prints:

1234567890 48192049281924
[download]

Update: Ok, here's a regex that does the trick. Let me know which you think more readable and maintainable. ;)

use strict;
use warnings;

my $str = '2222222222 1234567890 0000000000 48192049281924 99999999999
+999';
my @matched = $str =~ /
    [^\d]*
    (?:\b(?: 0{10,} | 1{10,} | 2{10,} | 3{10,} | 4{10,} | 5{10,} |
             6{10,} | 7{10,} | 8{10,} | 9{10,})\b [^\d]*
    )*
    (\b\d{10,}\b)
    (?:[^\d]* \b(?: 0{10,} | 1{10,} | 2{10,} | 3{10,} | 4{10,} | 5{10,
+} |
                    6{10,} | 7{10,} | 8{10,} | 9{10,})\b
    )*
    /gx;

print "@matched";
[download]

That regexp isn't going to work. Running it against a string of 10 identical numbers, it will match those 10 numbers.

my $str = '0000000000';
my @matched = $str =~ /
    [^\d]*
    (?:\b(?: 0{10,} | 1{10,} | 2{10,} | 3{10,} | 4{10,} | 5{10,} |
             6{10,} | 7{10,} | 8{10,} | 9{10,})\b [^\d]*
    )*
    (\b\d{10,}\b)
    (?:[^\d]* \b(?: 0{10,} | 1{10,} | 2{10,} | 3{10,} | 4{10,} | 5{10,
+} |
                    6{10,} | 7{10,} | 8{10,} | 9{10,})\b
    )*
    /gx;
say "@matched";
__END__
0000000000
[download]

The problem with your regexp is is that skipping sequences of 10 identical digits is optional. And that the heart, the (\b\d{10,}\b) part, isn't restrictive. And that Perl will do its utter best to find a match somehow, somewhere.

GrandFather's suggestion of filter out the false matches afterwards is probably sufficient for you, and perhaps also more efficient (but do a Benchmark to be certain if time efficiency is an issue). However, maybe you need this in a larger pattern, and then you can use a negative look-ahead to avoid the mono-digit strings.

$_ = '2222222222 1234567890 123 0000000000 48192049281924 999999999999
+99';

print "$2\n" while /\b(?!(\d)\1+\b)(\d{10,}\b)/g;

__END__
1234567890
48192049281924
[download]

lodin

Awesome suggestions everyone. I'll run some Benchmarks for sure and see how it works against my data. THANKS!

RegEx always seems to drive me nuts when I am trying to work on a project! Once I get the right expression(s) though, it is amazingly powerful :) My last project was for ISAPI URL rewrites.

/\b(\d)\1{9,}\b/
[download]

That only matches strings of 10 identical digits. Quite the opposite of what was asked.