Second, it sounds like simply binary searching your array for your upper bound and finding the first value less than that upper bound should get you your answer, as long as it's greater than your lower bound. No?

my @ordered_result_list = sort keys %results;
print $ordered_result_list[-1], "\n";
[download]

my %results = map { $_ => 1 if ( $low_watermark < $_ && $_ < $high_watermark ) } @all_numbers;

will get all of the matching numbers

Not if any of the numbers are duplicates because you are storing them in hash keys which will remove duplicates.

Why not just:

my @results = grep $low_watermark < $_ && $_ < $high_watermark, @all_n
+umbers;
[download]

I assumed an instance of the number was sufficient and that duplicates could be ignored, but you're absolutely right. I think grep would be a better call.

my @ordered_result_list = sort keys %results;
[download]

That's wrong. You're sorting lexically, so 10 comes before 9.

print sort 1..10;  # 1 10 2 3 4 5 6 7 8 9
[download]

The above is equivalent to

print sort { $a cmp $b } 1..10;  # 1 10 2 3 4 5 6 7 8 9
[download]

You want to sort numerically.

print sort { $a <=> $b } 1..10;  # 1 2 3 4 5 6 7 8 9 10
[download]

Of course, there's no reason to sort the result if you just want the highest.

use List::Util qw( max );

print max 1..10;  # 10
[download]

---

my %results = map { $_ => 1 if ( $low_watermark < $_ && $_ < $high_wat
+ermark ) } @all_numbers;
[download]

That's wrong. You're incorrectly assuming the expression in the map returns nothing when the condition is false.

$ perl -wle'my %h = map { $_ => 1 if $_ > 5; } 1..3; print 0+keys(%h);
+'
Odd number of elements in hash assignment at -e line 1.
1
[download]

You wanted:

my %results = map { if ( $low_watermark < $_ && $_ < $high_watermark )
+ { $_ => 1 } else { () } } @all_numbers;
[download]

Or:

my %results = map { ( $low_watermark < $_ && $_ < $high_watermark ) ? 
+$_ => 1 : () } @all_numbers;
[download]

But why is a hash involved at all?

my @results = grep { $low_watermark < $_ && $_ < $high_watermark } @al
+l_numbers;

print max(@results), "\n";
[download]

For that matter, why use max, since the natol44 specified "a sorted array of numbers"?

print $results[-1],"\n";
[download]

:)

Mike