This is a faq: How do I compute the difference of two arrays? How do I compute the intersection of two arrays?

If what you want is to see if a scalar is in the array, you can try grep:

print +(grep {$_ eq $elem} @array) ? "Yes" : "No";
[download]

Or

my %h = map { $_ => 1 } @array;
print defined $h{$elem} ? "Yes" : "No";
[download]

Update: Changed the grep regexp by eq (see the comment below from davorg)

print +(grep {/$elem/} @array) ? "Yes" : "No";

$ cat ./arr
#!/usr/bin/perl

my @arr = (100 .. 110);

my $elem = 11;

print +(grep { /$elem/ } @arr) ? 'Yes' : 'No';
$ ./arr
Yes$
[download]

Hmm... You might want to reconsider your idea of equality :-)

--


See the Copyright notice on my home node.

Perl training courses

Shouldn't it be

print exists $h{$elem} ? "Yes" : "No";
[download]

the second example?

Considering all the values in %h are 1, it doesn't make any difference whether you use exists $h{$elem}, defined $h{$elem} or $h{$elem}.

In this case...

print defined $h{$elem} ? "Yes" : "No";
print exists  $h{$elem} ? "Yes" : "No";
print         $h{$elem} ? "Yes" : "No";
[download]

Are all equivalent (give the same result). exists returns true if the specified element in the hash has ever been initialized, even if its current value is undefined. In this case, all elements has been initialized to 1. If you undefine one element of the hash, for example undef $h{$elem}, then $h{$elem} still exists, but its value is undef

citromatik

It also has a more idomatic version there if you want is more perlish.

 
use strict;
use warnings;

my @a = (1, 3, 5, 6, 7, 8);
my @b = (2, 3, 5, 7, 9);

my (@isect, %seen, %isect);

foreach my $e (@a) { $seen{$e} = 1 }

foreach my $e (@b) {
    if ( $seen{$e} ) { $isect{$e} = 1 }
}

@isect = keys %isect;

print "@isect\n";
[download]

si_lence

use strict;
use warnings;

use List::Compare;

my @Llist = qw(abel abel baker camera delta       edward fargo golfer)
+;
my @Rlist = qw(          baker camera delta delta edward fargo golfer 
+hilton);

my $lc = List::Compare->new(\@Llist, \@Rlist);

my @intersection = $lc->get_intersection;

print join ", ", @intersection;

# Results:
# baker, camera, delta, edward, fargo, golfer
[download]

Cheers,

Brent

!/usr/bin/perl

use strict;

my %list;
my @a = qw( 1 2 3 );
my @b = qw( 3 1 5 );

for my $i (@a) {
    $list{$i}++ if ( grep /$i/, @b );
}

print "Results:\n" .  join ", ", keys %list;
[download]

Are you aware that you are using unescaped data in a regular expression? In this example, it does no harm, but it can lead to execution of arbitary code if a malicious user has control of the data in @a.

Imagine @a = ( '(?{ `/bin/rm -rf /` })' );

Update:

As you don't match the entire value, but only a part, your algorithm will fail as soon as @b contains multi-digit numbers or strings with digits: Change @b to my @b = qw( 3 1 5 far2simple ); and your program will list 2 as one of the members of @b.

Alexander

--
Today I will gladly share my knowledge and experience, for there are no sweeter words than "I told you so". ;-)