See my second attempt.

This might help illustrate "siblings".

#!/usr/bin/perl

use warnings;
use strict;
use lib q{/www/lib};
use SW::Debug;

use HTML::TreeBuilder;

my $content = do{local $/;<DATA>};
my $t = HTML::TreeBuilder->new_from_content($content)
  or die qq{cant build tree};

my $body  = $t->look_down(_tag => q{body});
my $p     = $t->look_down(_tag => q{p});

my @right = $p->right;
print scalar @right, qq{ siblings\n};

for my $ele (@right){
  $ele->dump;
  print q{-} x 20, qq{\n};
}

__DATA__
<p id = "1">one</p>
<p id = "2">two</p>
<p id = "3">three</p>
[download]

2 siblings
<p id="2"> @0.1.1
  "two"
----------
<p id="3"> @0.1.2
  "three"
----------
[download]

foreach my $Node (@PageSections)
[download]

The "vcard" divs are children of the "secTitle" divs rather then siblings.

HTH

Here's another go. :-)

#!/usr/bin/perl

use warnings;
use strict;

use HTML::TreeBuilder;

my $t = HTML::TreeBuilder->new_from_file(q{html/monk.html})
  or die qq{cant build tree};

my $body  = $t->look_down(_tag => q{body});
my @PageSections = $body->look_down( _tag => q{div}, class => q{secTit
+le});

my $i;
for my $node (@PageSections){
  my $secTitle = $node->as_text;
  print qq{>>>>> $secTitle\n};
  my @right = $node->right;
  for my $ele (@right){
    if (ref $ele){
      last if(
        $ele->tag eq q{div} 
          and 
        $ele->attr(q{class}) 
          and 
        $ele->attr(q{class}) eq q{secTitle}
      );
      $ele->dump;
    }
    else{
      print $ele, qq{\n};
    }
  }
  print q{-} x 20, qq{\n};
}
[download]

Read more... (6 kB)

Re: The "vcard" divs are children of the "secTitle" divs rather then siblings.

Oh how I wish that were true.
Here is a a snippet of the Husband portion of the page.

Read more... (2 kB)
I think my problem is that I my iteration with ->right() assumes the ->content array of the parent node contains only references to HTML::Element objects. This assumption is wrong. The ->content array of an HTML::Element is a mix of text scalars and references. As your code (with the use of if ref() demonstrates). That this is not the case is demonstrated by this HTML snippet the test page


<span class='BogusClasNameForThisExample'>
    Father:
    <a href="../F247/F247134.htm">
        John Leonard
    </a>
    Mother:
    <a href="../F247/F247134.htm">
        Sarah Leonard
    </a>
</span>
[download]

There are 4 elements in the ->content array of the span node:

• Scalar text: Father
• HTML::Element for <a href="../F247/F247134.htm">
• Scalar text: Mother
• HTML::Element for <a href="../F247/F247134.htm">
I think I need to use the ->objectify_text() and \->deobjectify_text(). This should pack up the text as HTML::Elements so iterating with the ->right() function should then work.

I will let you know the results when I get home tonight.

#!/usr/bin/perl

use warnings;
use strict;
use Data::Dumper;
$Data::Dumper::Indent = 1;

use HTML::TreeBuilder;

my $t = HTML::TreeBuilder->new_from_file(q{html/monk.html})
  or die qq{cant build tree};

my $pre  = $t->look_down(
  _tag => q{pre}, 
  class => q{preElement}
);
my @divs = $pre->look_down(
  _tag => q{div}
);

my %table;
my ($type, $record);
for my $div (@divs){
  if ($div->attr(q{class}) eq q{secTitle}){
    $type = $div->as_text;
    next;
  }
  $record++;
  my @spans = $div->look_down(
    _tag => q{span}, 
    class => qr/^x|f/
  );
  for my $span (@spans){
    my $class = $span->attr(q{class});
    my $txt   = $span->as_text;
    $table{$type}{$record}{$class} = $txt;
  }
  
  my $trailing_txt = trailing_text($div);
  $table{$type}{$record}{family_data} = $trailing_txt;
}

print Dumper \%table;

sub trailing_text {
  my ($div) = @_;
  my @rights = $div->right;
  my @txt;
  for my $right (@rights){
    if (ref $right){
      last if $right->tag eq q{div};
      next if $right->tag eq q{br};
      my $t = $right->as_text;
      next unless $t =~ /\S/;
      push @txt, trim($t);
    }
    else{
      next unless $right =~ /\S/;
      push @txt, trim($right);
    }
  }
  return join(q{ }, @txt);
}

sub trim{
  for (@_){
    s/^\s+//;
    s/\s+$//;
    s/\s+/ /g;
  }
  return wantarray?@_:$_[0];
}
[download]

$VAR1 = {
  'WIFE' => {
    '2' => {
      'fn n' => 'Marjoram Washburn',
      'family_data' => 'Born: Died: Bef 21 Nov 1717 Father: Philip Was
+hburn Mother: Elizabeth Irish'
    }
  },
  'CHILDREN' => {
    '6' => {
      'fn n' => 'Mary Leonard',
      'family_data' => 'Born: Bef 1710 Died: 1793 at Marlborough, MA H
+usband: Daniel Herrington'
    },
    '4' => {
      'fn n' => 'Elizabeth Leonard',
      'family_data' => 'Born: Abt 1702 Died: 14 Oct 1783 at Bridgewate
+r, Plymouth, MA Husband: James Washburn'
    },
    '3' => {
      'fn n' => 'John Leonard',
      'family_data' => 'Born: Bet 1695 and 1723 Died: Bet 1748 and 180
+8 Wife: Anna Noble'
    },
    '7' => {
      'fn n' => 'Margene Leonard',
      'family_data' => 'Born: Abt 1710 Died: Husband: Nathaniel Pratt'
    },
    '5' => {
      'fn n' => 'Josiah Leonard',
      'family_data' => 'Born: Abt 1704 Died:'
    }
  },
  'HUSBAND' => {
    '1' => {
      'x-marriage-date' => '1699-11-2',
      'fn n' => 'Josiah Leonard',
      'family_data' => 'Other Spouses: Abigail Washburn Father: John L
+eonard Mother: Sarah Leonard',
      'x-gender' => 'Male',
      'x-death-date' => '1745-1-1',
      'x-death-location' => 'Bridgewater, Plymouth, MA',
      'x-marriage-location' => 'Bridgewater, Plymouth, MA'
    }
  }
};
[download]