The values in a hash can be any kind of scalar. To get the results that you want, each value would need to be a reference to an array, and each element in the referenced arrays would need to be another array reference.

%number = ( 23 => [ [ 'g1', 23, 24 ], [ 'g2', 34, 35 ] ],
            24 => [ [ 'g3', 45, 56 ], [ 'g4', 36, 48 ] ],
          );
$grp = $number{23}[0][0];
[download]

Note the I've corrected your hash-creating brackets from {} to ().

For more details see perldsc.

in case i have new set of data (new array) referring to same key,is it possible to push the array value to the hash? eg :

new set is read from a file

while ($line <>){
($key,$value)=split(/,/,$line);
#suppose #line have 23,['g8',23,45]
push @{$numbers{23}},$value;
}
[download]

will this append the new array to existing key ?

What you're looking for is probably more like:

while (<>) {
  chomp;
  my ($key, @values) = split /,/, $_;
  push @{$numbers{$key}}, [ @values ];
}
[download]

When playing with complex data structures, perldsc and Data::Dumper are your friend.

--


See the Copyright notice on my home node.

Perl training courses

Close. A hash value is a scalar so you need a reference to an array. In fact you want a reference to an array of arrays so that looks like:

use warnings;
use strict;

my %number = (
    23 => [['g1', 23, 24], ['g2', 34, 35]],
    24 => [['g3', 45, 56], ['g4', 36, 48]],
);

print "First group is: $number{23}[0][0]\n";
[download]

Prints:

First group is: g1
[download]

Note the use of () (not {}) for the initialization list for the hash and that the group names need to be quoted.

#!/usr/bin/perl

use strict;
use Data::Dumper;

my %number = ( 23 => [ qq[g1,23,24], qq[g2,34,35] ],
               24 => [ qq[g3,45,56], qq[g4,36,48] ]
             );

$number{25}->[0] = qq[g5,55,56];

print Dumper \%number;
[download]