Do you have any better idea to avoid the empty element ?

Yeah, don't use split to parse something that isn't a uniform list.

At a minimum, you could use the following:

my @var = $test =~ /\d+/g;
[download]

A little more flexible:

my ($list) = $test =~ /\[ ( [^\]]* ) \]/x;
my @var = split /,/, $list;
[download]

By the way, the following needlessly creates two variables that are never used (and issues a warning for having two variables with the same name):

my $empty;
my ($empty,@var) = ...;
[download]

You want:

(undef, my @var) = ...;
[download]

Update: Fixed pattern.

This should work better:

my $test="[1,2,3]";

my @var = $test =~ /\d+/g;

print Dumper \@var;
[download]

This works fine for numbers only, the element may be any character, In this case what can I do ?

my $test = "[1,2,3]";

my @var = $test =~ /[^][,]+/g;

print Dumper \@var;
[download]

The second example given by ikegami above should work for you , provided you have a defined separator that doesn't conflict with your data.

As I know that I get the empty element at first

Or grep away null elements. I admit that I do this sometimes simply to save cognitive load as opposed to CPU load.

my @array = ('',1,2,'',3,'',4);
@array = grep { $_ } @array;
print join "}{",@array;
print "\n";
[download]

gives

1}{2}{3}{4
[download]

@array = grep { $_ } @array;

This grep also removes array elements that happen to be 0. Use grep { defined && length } instead if you want to have the 0 elements in the result.

Alexander

--
Today I will gladly share my knowledge and experience, for there are no sweeter words than "I told you so". ;-)

ree:

I see you've got plenty of responses from which to choose. But I thought I'd comment anyway. Since you have a variety of methods now at your fingertips, how do you select the one you should use in your application? By looking them over while paying attention to the stated/unstated assumptions.

• Capture only the items you want like:
  my @var = $test =~ /\d+/g; The important assumption in this solution is that the items you want are strings of digits.
• Regex capture followed by split
  my ($list) = $test =~ /\[ ( [^\]]+ ) \]/x, $1); my @var = split /,/, $list; The assumptions here are: (a) your string always contains an argument list surrounded by [ and ].
• Explicitly ignore the first item in an array assignment
  (undef, my @var) = ...; Assumes you always want to delete the first item in the list. As rofv mentions above, another way to ignore the first item is to just use shift after creating your @var array.
• I was originally going to suggest you filter out the empty items (via grep). The assumption being that you don't want any empty items anywhere in your list.

By paying attention to the assumptions your code makes and the assumptions the proposed solutions make, you can select a method with the fewest mismatched assumptions. Note also that assumptions are closely related to constraints--learning to see the assumptions made by code also helps you to recognize constraints in your code. As you recognize them, you can avoid adding gratuitous constraints to your programs.

...roboticus

Update: Replaced empty NOTES: at end with an Update: block. (I removed the item requiring a note without removing the notes block....)

use Data::Dumper;
my @els = '[1,2,3]' =~ /(\w+)/g;
print Dumper \@els;
[download]

$VAR1 = [
          '1',
          '2',
          '3'
        ];
[download]