in reply to Re^2: Check if Date interval contains Hour X
in thread Check if Date interval contains Hour X

The very first thing that came to my mind after reading the OP was the method DateTime::Span::contains. However, yours is the right approach since that method only works for sets that are fully inside, as the manual says.

Thanks!

Replies are listed 'Best First'.
Re^4: Check if Date interval contains Hour X
by ikegami (Patriarch) on Jul 23, 2009 at 20:26 UTC
    contains wouldn't work, but intersects would 
    ...| 20 | 21 | 22 | 23 | 00 | 01 | 02 | 03 |...
                  (------------)     log
                            (----]   hour
                            (--)     intersection

    [download]
[reply]
[d/l]
[select]

      You're right again, I just realized a bit later so I've been playing with intersects:

      sub hour_in_range {
    my ($dt_s, $dt_e, @hours) = @_;

    my $dt_span = DateTime::Span->from_datetimes(
        start => $dt_s, end => $dt_e
    );

    for my $hour (@hours) {
        my $dt = $dt_s->clone()
                      ->truncate( to => 'day' )
                      ->add( hours => $hour );

        $dt->add( days => 1 ) if $dt < $dt_s;

        my $hour_span = DateTime::Span->from_datetimes(
            start => $dt, end => $dt
        );

        return 1 if $dt_span->intersects($hour_span);
    }

    return 0;
}

      [download]

      It's not as simple and efficient as your approach, but it shows how to use span intersection.

      OTOH, I misunderstood the OP and was thinking that @hours = (1,11) was an interval (1am to 11am), not a list of hours to match.

[reply]
[d/l]
[select]
                my $hour_span = DateTime::Span->from_datetimes(
            start => $dt, end => $dt
        );

        [download]

        should be 

                my $hour_span = DateTime::Span->from_datetimes(
            start => $dt, before => $dt->clone()->add( hours => 1 ),
        );

        [download]

        or the more readable 

                my $hour_span = DateTime::Span->new(
            start => $dt, hours => 1,
        );

        [download]

        Update: No, neither fix help. They were suppose to make the following match: 

        2010-10-10 01:59:59|2010-10-10 01:59:59|blablalblabla

        [download]

        You need 

        sub hour_in_range {
    my ($dt_s, $dt_e, @hours) = @_;

    my $dt_span = DateTime::Span->from_datetimes(
        start => $dt_s, end => $dt_e
    );

    for my $hour (@hours) {
        my $dt = $dt_s->clone()
                      ->truncate( to => 'day' )
                      ->add( hours => $hour );

        my $dt_tomorrow = $dt->clone()->add( days => 1 );

        my $hour_span = DateTime::Span->new(
            start => $dt, hours => 1
        )->union( DateTime::Span->new(
            start => $dt_tomorrow, hours => 1
        ));

        return 1 if $dt_span->intersects($hour_span);
    }

    return 0;
}

        [download]

        And there you go, the four DateTimes per hour I mentioned earlier.

[reply]
[d/l]
[select]

In Section Seekers of Perl Wisdom