Neither of those snippets is doing what you think it is. Look at what B::Deparse tells you.

% perl -MO=Deparse -e 'print "TRUE" if ( 0 ) or die "FALSE"'
print 'TRUE' if die 'FALSE';

% perl -MO=Deparse -e 'print "TRUE" if ( 0 ) or print "FALSE"'
print 'TRUE' if print 'FALSE';
[download]

Basically, Statement Modifiers are the last thing on a line, so your if ( 0 ) or die "FALSE" actually means if( (0) or die "FALSE"). And the return value of the die (or print) is what determines whether your initial print actually runs. Since print is returning something true, and die doesn't return, you end up with the results you saw.

Incidentally the built in trinary function does exactly what you are trying to do. The pattern for that looks like this:

CONDITION ? do_if_true() : do_if_false();
[download]

0 ? print "TRUE" : print "FALSE";
[download]

print( 0 ? "TRUE" : "FALSE" );
[download]

"( 0 )" is the same as "0", and "0 or EXPR" is the same as just "EXPR".

That means
print "TRUE" if ( 0 ) or die "FALSE";
is equivalent to
print "TRUE" if die "FALSE";
And since die doesn't return, the above is equivalent to just
die "FALSE";

That means
print "TRUE" if ( 0 ) or print "FALSE";
is equivalent to
print "TRUE" if print "FALSE";
which prints FALSE, and if successful, also prints TRUE.

You seem to be under the impression that "print "TRUE" if ( 0 )" is an expression (rather than a statement) or that the operands of "or" can be statements. Neither is the case.

The differences you see come about because or takes precedence over if. Because of this, or doesn't act like "else". Instead it turns its neighbors into a single condition used by if. If you put in parenthesis to explicitly show precendence, the two statements you wrote above look like this:

print "TRUE" if (0 or die "FALSE");
print "TRUE" if (0 or print "FALSE");

#or alternatively

if (0 or die "FALSE") {
   print "TRUE";
}
if (0 or print "FALSE") {
   print "TRUE";
}
[download]

Once you see the precedence, the difference in behavior is obvious: when 0 or die "FALSE" gets evaluated it dies before ever getting to what is inside of if {...}. On the other hand, 0 or print "FALSE" evaluates to true and causes Perl to enter inside of the if {...} statement. Hence, "FALSETRUE" gets printed.

Best, beth

print "TRUE" if ( 1 ) or die "FALSE"  ;
print "TRUE" if ( 2 ) or die "FALSE"  ;
print "TRUE" if ( 3 ) or print "FALSE"  ;
print "TRUE" if ( 4 ) or print "FALSE"  ;
[download]

Your code addresses a precedence issue as ELISHEVA clarified too (UPDATE)

I think what you're asking is "how do I write a postfix if, with an else part?" The answer is a rare one in perl - "you can't".

The following are some alternatives, all equivalent. I have replaced your if(0) with a $test variable which is true 50% of the time.

    use 5.010; #gives you 'say'
    my $test = rand > 0.5;

    # two postfix tests:
    say 'TRUE' if $test;
    say 'FALSE' if not $test;

    # a one-liner conventional if
    if($test) { say 'TRUE' } else { say 'FALSE' }

    # two lines, using 'and' and 'or':
    $test and say 'TRUE';
    $test or say 'FALSE';

    # a ternary (my favourite):
    say $test ? 'TRUE' : 'FALSE';
[download]