Like japhy said, look into Carp. However, it sounds like that isn't what you're looking for...are you saying that none of your die messages include any line/filename info? In that case, this suggests that your die() message strings all end in '\n'. If you remove those newlines, you'll get that information. Alternatively, if you replace each die() with croak(), the '\n' won't prevent a line-number from appearing (although it will push that information onto the next line). As an alternative, rather than going line-by-line through your code, just adding this should give you what you want:

BEGIN {
  $SIG{__DIE__} = sub {
      my $string = shift;
      chomp($string);
      my ($package, $file, $line) = caller;
      die "$string [at $file, line $line]\n" 
          unless ($package eq 'Carp');
  }
}
[download]

Modifying $SIG{__DIE__} like this changes how all of your die() calls behave (including croak(); that last bit with the 'unless' is in there to keep the output from getting too ugly). If you want the same sort of thing for warn() and carp(), you can modify $SIG{__WARN__}.

Update: I had croak() and carp() switched in the last paragraph there (thanks premchai21).

Update++:Also, tilly's post above this one (about checking $^S) applies to what I'm doing here. Here's how I think this ought to be taken into account (with confess thrown in for a complete trace of the call-stack (thanks again tilly)):

BEGIN {
  $SIG{__DIE__} = sub {
      my $string = shift;
      chomp($string);
      my ($package, $file, $line) = caller;
      confess "$string\n" if
         ((defined ($^S)) and not $^S);
  }
}
[download]

-- Frag.

If you read the question closely, what the person wants is a call-stack. The die is happening from read_file. But that information is useless because everything has to read files. What you really want to know is where you were 2 calls back, in parse_template. For that you really wanted to use Carp's confess.

I think you're a bit mixed up here. croak() calls die() and carp() calls warn(), not vice versa.

This looks better than the first two suggestions;
alternatively, you can replace the CORE::die function with
your own; to start see:

Bekman, Stas. mod_perl guide, chapter 3.12

humbly,
novitiate

sub DIE { 
  my $i=0; 
 
  while (my @info=caller($i++)) { 
        print STDERR "$info[3]($info[2]) "; 
 }                
  
  print STDERR ": "; 
  printf STDERR @_; 
  print STDERR "\n"; 
 
  exit 1; 
}
[download]

main::DIE(16) main::foo(19) main::ack(22) main::bar(25) : HI
[download]

sub foo { 
        DIE "HI"; 
} 
sub ack { 
        foo; 
} 
sub bar { 
        ack; 
} 
 
bar();
[download]

If you wanted a caller output and then a normal die, I would suggest something like (untested):

sub DIE {
  my $i=0; 
  my $buff;

  while (my @info=caller($i++)) { 
        $buff.="$info[3]($info[2]) "; 
 }                

 die $buff;
}
[download]

Please, please, please check $^S if you are going to change the behaviour of die like this. You have no idea what libraries you will mutilate that use eval/die to catch normal exceptions in program flow (eg alarm timeouts) that don't want to be turned into an untrappable fatal error.

Please build up a string and just redie with that string. Even better, use eval { ... } around the heart of your code instead. __DIE__ handlers have some bad design flaws and your code is exercising most of them.

Sorry, I think tilly's reply fooled me. You aren't using a __DIE__ handler nor overriding die.

<Emily Latela>Never mind</Emily Latela>

        - tye (but my friends call me "Tye")