bichonfrise74 has asked for the wisdom of the Perl Monks concerning the following question:

It all began when I was playing with indirect filehandles. I have a small code below where I want to simply open an input file and print its content into an output file. 
#!/usr/bin/perl

use warnings;
use strict;

open( my $output, '>', '/tmp/output.txt' )
  or die "Error: Cannot open the file - $!\n";

open( my $input, '<', '/tmp/input.txt' )
  or die "Error: Cannot open the  file - $!\n";

print {$output} while (<$input>);   ## This is were the problem is.

close( $input );
close( $output );

[download]
When I run this code, I get this error. 
syntax error at test.pl line 12, near "} while"
Execution of test.pl aborted due to compilation errors.

[download]
This is referring to the line print {$output}...
If I change this line to remove the brackets between the variable $output, 
print $output while (<$input>);

[download]
And running it, I get this on the standard output, and no output file is created. 
GLOB(0x84f3bdc)GLOB(0x84f3bdc)....

[download]
Finally, when I change the line to this... 
print {$output} $_ while (<$input>);
or
print $output $_ while (<$input>);

[download]
Then everything is okay. My question is why do I have to explicitly write $_ in the above cases? I would assume that the content of $_ is changing, but I'm not sure where and I'm not sure if this assumption is even correct.

And compare this to the code below where I do not use indirect filehandles to write to an output file. Note that in the code below, I do not need to explicitly write $_ when printing the output. I was expecting that I can do the same with indirect filehandles. 
#!/usr/bin/perl

use warnings;
use strict;

open( OUTPUT, '>', '/tmp/output.txt' )
  or die "Error: Cannot open the file - $!\n";

open( my $input, '<', '/tmp/input.txt' )
  or die "Error: Cannot open the  file - $!\n";

print OUTPUT while (<$input>);

close( $input );
close( OUTPUT );

[download]

Replies are listed 'Best First'.
Re: Printing with Indirect FileHandles
by ig (Vicar) on Aug 26, 2009 at 00:32 UTC

    update: revised to recognize the evidence of your last example.

    print says print only prints $_ if neither a filehandle nor an argument list is provided, except that your last example demonstrates that it does not behave exactly as print says it does.

    You could use the following:

    use strict;
use warnings;
open( my $output, '>', '/tmp/output.txt' )
    or die "Error: Cannot open the file - $!\n";

open( my $input, '<', '/tmp/input.txt' )
    or die "Error: Cannot open the  file - $!\n";

select $output;
print while (<$input>);   ## This is were the problem is.

close( $input );
close( $output );

    [download]
[reply]
[d/l]
[select]

      except that your last example demonstrates that it does not behave exactly as print says it does.

      How so?

      In print {$output} $_, nothing is omitted, so what is specified to print is printed to the specified handle.

      In print $output $_, nothing is omitted, so what is specified to print is printed to the specified handle.

      In print $output, the file handle is omitted, so $output is printed to the currently selected handle.

      And the first, print {$output}, is not one of the valid forms.

[reply]
[d/l]
[select]

        In print OUTPUT while (<$input>); a file handle is given but no list. print doesn't even admit in the synopsis that such a case is possible and it says:

        If LIST is also omitted, prints $_ to the currently selected output channel.

        My emphasis.

[reply]
[d/l]
        Thanks. And what is the explanation as to why print OUTPUT works?
[reply]

Back to Seekers of Perl Wisdom