global vars and one liners

punkish has asked for the wisdom of the Perl Monks concerning the following question:

So, I am trying to learn one liners. I start with the following trivial script that loops over a DATA handle and prints out all the uniq words.

#!/usr/local/bin/perl

while(<DATA>) {
    /(\w*)/;
    $i{$1}++;
}

print "$_\n" for keys %i;

__DATA__
foo
bar
baz
qux
foo
foo
bar
baz
qux
[download]

Now, I want to convert this into a one liner, assuming the words are in a separate file called words.txt. So, I tried the following and failed

perl -nle '/(\w*)/;$i{$1}++;print for keys %i;' words.txt
[download]

The reason, of course, is that %i is not remembered from one iteration to the other. How do I create this one liner?

--

when small people start casting long shadows, it is time to go to bed

Comment on global vars and one liners Select or Download Code

Replies are listed 'Best First'.
Re: global vars and one liners by jethro (Monsignor) on Sep 15, 2009 at 01:16 UTC
Wrong reason. i don't know what you got when you tried your one liner, but you should have seen something like this: `foo foo bar foo bar baz ...` [download] (because of the randomness of the hash not exactly in this sequence) Reason is that your small for-loop is inside the while-loop created by -e. To rectify this you could replace the inner loop with an 'if': `perl -nle '/(\w)/; print if (not exists $i{$1}); $i{$1}++;' words.txt` [download] If you really need to do the printing after the loop, you could use END (the seldom used opposite of BEGIN): `perl -nle '/(\w)/;$i{$1}++; END{print for keys %i;} ' words.txt` [download]	[reply] [d/l] [select]
Re: global vars and one liners by AnomalousMonk (Archbishop) on Sep 15, 2009 at 01:09 UTC
... %i is not remembered from one iteration to the other. On the contrary, `%i` is remembered perhaps too well, being printed entirely for every line (iteration) in the file. Consider the following modification (my file `words2.txt` has the same data as given in the OP): `>perl -nle "/(\w)/; $i{$1}++; print qq{$. $_} for keys %i;" words2.txt 1 foo 2 bar 2 foo 3 bar 3 baz 3 foo 4 bar 4 baz 4 qux 4 foo 5 bar 5 baz 5 qux 5 foo 6 bar 6 baz 6 qux 6 foo 7 bar 7 baz 7 qux 7 foo 8 bar 8 baz 8 qux 8 foo 9 bar 9 baz 9 qux 9 foo` [download] Maybe try something like: `>perl -wMstrict -lne "/(\w+)/; $::i{$1}++; END { print qq{$_ $::i{$_}} for keys %::i } " words2.txt bar 2 baz 2 qux 2 foo 3` [download] Update:* removed extraneous `BEGIN { ... }` block from second example.	[reply] [d/l] [select]
Re^2: global vars and one liners by AnomalousMonk (Archbishop) on Sep 15, 2009 at 02:08 UTC
Or maybe just ditch the `-n` command line switch altogether: `>perl -wMstrict -le "for (<>) { /(\w+)/; $::i{$1}++ } print qq{$_ $::i{$_}} for keys %::i " words2.txt bar 2 baz 2 qux 2 foo 3` [download]	[reply] [d/l] [select]
Re: global vars and one liners by jwkrahn (Abbot) on Sep 15, 2009 at 08:34 UTC
`$ echo "foo bar baz qux foo foo bar baz qux" \| perl -lne'@i{/\w+/g}=()}{print for keys%i' bar baz qux foo` [download]	[reply] [d/l]
Re^2: global vars and one liners by AnomalousMonk (Archbishop) on Sep 15, 2009 at 14:36 UTC
`>perl -wMstrict -lne "@::i{ /\w+/g } = () }{ print for keys %::i" words2.txt bar baz qux foo` [download] OK, it works (Windose)! Now c'mon, how's it work? What's that strange `}{` thingy in the middle of it all? Can you give a documentation ref. for more info on that?	[reply] [d/l] [select]
Re^3: global vars and one liners by ccn (Vicar) on Sep 15, 2009 at 19:21 UTC
It is so called eskimo operator: }{ see perldoc perlrun about -n switch and compare output of the following two commands `perl -MO=Deparse -ne "$a + $b" perl -MO=Deparse -ne "$a }{ $b"` [download] Note: double quotes because of Windows. Linux requires single quotes for the code given	[reply] [d/l]