in reply to Re^3: Improve foreach with help of map?
in thread Improve foreach with help of map?

You are indeed correct, my bad. It does thought have the problem in this case to make the regex very complex since the first match kind of identifies position and then the second rexegp gets the actual value. Between the first and second match there is ALOT of crap.

In this case it look something like. 

<td><b>End Date</b></td>^M
<td><img src="http://welcome.hp-ww.com/img/s.gif" idth="1" height="1" 
+border="0" alt=""></td>^M
<td>^M
19 Jun 2012^M

[download]

So the regexp would first have to match "End Date" and then the actual date and ignore everything between.

I tried something like:

my ($result) = $content =~ /End Date.*(\d\d \w\w\w \d\d\d\d)/;

[download]

But it seems there's just to much crap between the lines.

The fine example of HTML is from HP. It's feels like 1994 all over again.

Replies are listed 'Best First'.
Re^5: Improve foreach with help of map?
by wfsp (Abbot) on Oct 09, 2009 at 15:27 UTC
    For completness, the long version not using a regex. :-) 
    #!/usr/bin/perl

use warnings;
use strict;
use HTML::TreeBuilder;

my $html = do{local $/;<DATA>};

my $t = HTML::TreeBuilder->new_from_content($html);

my $start;
for my $td ($t->look_down(_tag => q{td})){
  $start++, next if $td->as_text eq q{End Date};
  next unless $start;
  next if $td->look_down(_tag => q{img});
  print $td->as_text;
  last;
}

__DATA__
<td><b>End Date</b></td>
<td><img src="http://welcome.hp-ww.com/img/s.gif" width="1" height="1"
+ border="0" alt=""></td>
<td>
19 Jun 2012

    [download]
[reply]
[d/l]
Re^5: Improve foreach with help of map?
by ikegami (Patriarch) on Oct 09, 2009 at 15:22 UTC
    I just gave basically the same solution. The difference it that mine works ;) You'll need two fixes to make yours work:
    • Use the /s modifier. /./ needs to match newline.
    • Change /.*/ to /.*?/. You want to next date, not the last date.
[reply]
[d/l]
[select]
Re^5: Improve foreach with help of map?
by JavaFan (Canon) on Oct 09, 2009 at 15:37 UTC
    Use this: 
    $content =~ /End Date/g and $content =~ /(\d\d \w\w\w \d\d\d\d)/g and 
+my $result = $1;

    [download]
[reply]
[d/l]
      Nice, although second /g should be omitted
[reply]
        Perhaps you should actually try your suggestions first. It will not work correctly if you omit the second /g. 
        my $content = <<EOT;
Blah blah
12 Feb 1992  # Wrong date!
Mah Mah Mah
End Date: 14 Jul 2007 # Correct date!
EOT

$content =~ /End Date/g
     and $content =~ /(\d\d \w\w\w \d\d\d\d)/
     and my $result1 = $1;

say "Ikegami's end date: $result1";

pos($content) = 0;

$content =~ /End Date/g
     and $content =~ /(\d\d \w\w\w \d\d\d\d)/g
     and my $result2 = $1;

say "JavaFan's end date: $result2";
__END__
Ikegami's end date: 12 Feb 1992
JavaFan's end date: 14 Jul 2007

        [download]
[reply]
[d/l]
[select]

In Section Seekers of Perl Wisdom