markkawika has asked for the wisdom of the Perl Monks concerning the following question:

What's a simple way to add the elements of two arrays together? Something like this: 

$list1[0] += $list2[0];
$list1[1] += $list2[1];
$list1[2] += $list2[2];
$list1[3] += $list2[3];

[download]

The solution that occurs to me is: 

for my $i (0..3) {
  $list1[$i] += $list2[$i];
}

[download]

What if instead of an array, you have a list (or, at least, you could make a list)? Something like this: 

$some_value += $array[0];
$some_other_value += $array[1];
$this_variable += $array[2];
$that_variable += $array[3];

[download]

That doesn't seem to lend itself as handily to a simple for loop.

Replies are listed 'Best First'.
Re: Adding two lists together
by jwkrahn (Abbot) on Nov 05, 2009 at 00:55 UTC 
    use List::MoreUtils 'pairwise';

pairwise { $a += $b } @list1, @list2;

    [download]
[reply]
[d/l]
      ... and to suppress the annoying warnings: 
      use strict;   
use warnings;
use Data::Dumper;
use List::MoreUtils qw(pairwise);

my @list1 = (1 .. 5);
my @list2 = (11 .. 15);
{
    no warnings;
    pairwise { $a += $b } @list1, @list2;
}
print Dumper(\@list1);

__END__
$VAR1 = [
          12,
          14,
          16,
          18,
          20
        ];

      [download]
      List::MoreUtils
[reply]
[d/l]
Re: Adding two lists together
by shmem (Chancellor) on Nov 05, 2009 at 00:44 UTC

    You could use a statement modifier:

    $list1[$_] += $list2[$_] for 0..$#list1;

    [download]

    Assignment to a list of variables: 

    ($some_value, $some_other_value, $this_var, $that_var)
    = @array;

    [download]
[reply]
[d/l]
[select]
Re: Adding two lists together
by colwellj (Monk) on Nov 05, 2009 at 00:13 UTC
    Mark,

    For the 2 lists try this to always get every item. This assumes that the list2 has at least as many elements as list one though 
    for my $i(0..$#list1){
   $list1[$i] += $list2[$i];
}

    [download]
    For the non list how about; 
    my @list2;
push @list2, $some_value, $some_other_value, $this_variable, $that_var
+iable;
for my $i(0..$#list1){
   $list1[$i] += $list2[$i];
}

    [download]
    I'm not sure if its really worth it however.

    John
[reply]
[d/l]
[select]
      Another approach to the pesky 'list of scalars': 
      >perl -wMstrict -le
"use List::MoreUtils qw(each_array);
 my ($w, $x, $y, $z) = ( 1,  2,  3,  4);
 my @incs            = (10, 20, 30, 40);
 my $ea_inc = each_array @incs;
 $_ += $ea_inc->() for $w, $x, $y, $z;
 print qq{w $w   x $x   y $y   z $z};
"
w 11   x 22   y 33   z 44

      [download]
      Note that nothing is done here to check that the list and the array have the same number of elements!
[reply]
[d/l]

Back to Seekers of Perl Wisdom