You probably meant my $number=shift; (not $my number=shift; — though that would produce a different error message).

Other than that, I don't see anything wrong with testing not defined ($array[$number]) to do what you want, and in fact it does work just fine for me... (in other words, I suppose the problem lies elsewhere).

#!/usr/bin/perl

use strict;
use warnings;

my @array;
$array[70] = "foo";

asubroutine(20);

sub asubroutine   {
    my $number=shift ;   # $number takes the value of 20
    if ( not defined ($array[$number]))    {    
       print "There is no such element $number in the array.\n";
    }
}

__END__
There is no such element 20 in the array.
[download]

How about starting with your code and a tiny sample input data set that demonstrates the issue. Then whittle the code down to a smallest possible test script that still demonstrates the problem. Then show us the result - if you've not solved the problem yourself in the process.

It is very likely that there is an interaction going on between parts of your code that you haven't noticed. At some point in the whittling process your are almost certain to make the connection.

Am I to assume that elements 0-69 and 71-120 are undefined?

Yes. If they were undefined, they will remain undefined.

$ perl -le'
    my @a;
    print 0+@a;
    print defined($a[0]) || 0;
    $a[70] = "a";
    print 0+@a;
    print defined($a[0]) || 0;
'
0    0 elements in the array
0        and the first one isn't defined.
71   71 elements in the array
0        and the first one still isn't defined.
[download]

My problem is that not defined ($array[$number] returns false

Then $array[$number] is defined. It was given a value somewhere else, possibly through autovivification.

$ perl -le'
    my @a;
    print defined($a[0]) || 0;
    $a[0][0];
    print defined($a[0]) || 0;
'
0
1
[download]

[@{$x->[3]}>0 gives] Can't use an undefined value as an ARRAY reference

Then $array[$number][3] is not defined.

Update: Added code blocks.

perl -le '
$a[10] = 1;
if (exists $a[2]) {
  print "how did that get there?\n";
} else {
  print "a[2] does not exist\n";
}
'
a[2] does not exist
[download]

That's bad advice. You should never have to use exists on an array element. It returns useless information and doesn't solve the problem you claims it solves (as explained by almut).

See modules autovivification and warnings::autoviv. (Well, the latter doesn't exist yet. Working on it.)

and will not auto-vivify them

defined will not autovivify either:

my @array;
if (defined $array[20]) { }                           # no autovivific
+ation, thus
if (defined $array[20]) { warn "[20] does exist!" }   # no warning
[download]

Typically, it's a dereferencing operation that unexpededly autovivifies.  exists shares the same problem:

my @array;
if (exists $array[20]->[42]) { }
if (exists $array[20]) { warn "[20] does exist!" }

__END__
[20] does exist! at ./808911.pl line 5.
[download]

I should have been more clear - defined does not distinguish between "never existed" and "is undef" for hash and array elements. I therefore consider exists a better test for unexpected auto-vivification.