use strict;
use warnings;
use Time::Duration::Parse qw(parse_duration);
use Time::Duration qw(duration);
use List::Util qw(sum);

my @times = <DATA>;
my $count = @times;
my $sum   = sum map { parse_duration($_) } @times;
my $avg   = $sum / $count;

print duration($sum, 3), "--Total Time\n";
print duration($avg, 3), "--Avg Time\n";

__DATA__
2:11:20
2:07:44
2:18:41
0:40:17
2:40:53
1:27:21
4:03:43
1:54:42
1:59:40
2:08:49
2:12:21
[download]

23 hours, 45 minutes, and 31 seconds--Total Time
2 hours, 9 minutes, and 35 seconds--Avg Time
[download]

Or just split each string and do the math yourself. And be sure to check for blank or not-valid strings.

Briefly, the Monastery is a place to get help on your own efforts; to learn; NOT to ask others to write your code.

You've got an answer, with code, so I'm going to give you some generic advice.

When you're being asked to average or total anything, your first step will be to convert everything to a standard unit (for time, I'd pick seconds), do the arithmetic with that unit, and then convert it to something that is easier for people to read (I'd be happy with an answer like 85 531 seconds, but that's just me). Obviously, some error checking is required, including the obvious checks to make sure that the H:M:S times don't include nonsense, like 4:103:99

my $total_time = 0;
my $num_records = 0;

while (<DATA>) {
    chomp;
    my ($hour, $min, $sec) = split /:/;

    $total_time += $hour * 3600 + $min * 60 + $sec;
    ++$num_records;
}

print format_time($total_time), "--Total Time\n";
print format_time($total_time/$num_records), "--Avg Time\n";

sub format_time {
    my $seconds = shift;

    my $hours = int($seconds / 3600);
    my $minutes = int($seconds / 60 - $hours * 60);
    my $sec = int($seconds - $hours * 3600 - $minutes * 60);

    sprintf "%02d:%02d:%02d", $hours, $minutes, $sec;
}
[download]