Re: How to open files found via File::Find

You're not getting the errors you should because

open INFILE,'<$name'  || warn ("Cannot open input file $name\n");
[download]

means

open INFILE, ( '<$name' || warn ("Cannot open input file $name\n") );
[download]

which is the same as the following (since '<$name' is always true):

open INFILE, '<$name'
[download]

You want to use parens or lower-precedence "or":

open(INFILE, '<$name')
   || warn ("Cannot open input file $name\n");
[download]

open INFILE, '<$name'
   or warn ("Cannot open input file $name\n");
[download]

Then there's the problem that '<$name' produces the five character < $ n a m e. You need to use double-quote to interpolate.
```
open(INFILE, "<$name")
   or warn ("Cannot open input file $name\n");
[download]
```
Or better yet, use the safer, more reliable 3-arg open:
```
open(INFILE, '<', $name)
   or warn("Cannot open input file $name: $!\n");
[download]
```

Finally, $_ only contains the name of the file, not the path to the file. You need to use $File::Find::name.
open(INFILE, '<', $File::Find::name) or warn("Cannot open input file $File::Find::name: $!\n");
[download]

There's also a problem with
```
"$directory\$name"
[download]
```
The backslash before the $ tells Perl to treat the $ as a non-special character. You want
```
"$directory\\$name"
[download]
```
The following would also be fine:
```
"$directory/$name"
[download]
```
Yes, even on Windows. Windows accepts both slashes.

Comment on Re: How to open files found via File::Find Select or Download Code

Replies are listed 'Best First'.
Re^2: How to open files found via File::Find by jwkrahn (Abbot) on Jan 08, 2010 at 07:28 UTC
Finally, `$_` only contains the name of the file, not the path to the file. You need to use `$File::Find::name`. Actually, `File::File::find()` changes directories while tranversing the file system so `$_` doesn't need the path because `$_` is in the CWD (which is in `$File::Find::dir`).	[reply] [d/l] [select]