use strict;
use vars qw($tmp_dir $dir);

open OUTPUTFILE, ">test.txt";

$tmp_dir = "test";
$dir = "tester";

if ($tmp_dir ne $dir) {
    print "dumping to file\n";
    print OUTPUTFILE "\n$tmp_dir\n";
    $dir = $tmp_dir;
}
[download]

unless($tmp_dir eq $dir){
    print OUTPUTFILE "\n", $tmp_dir ,"\n";
    $dir = $tmp_dir;
}
[download]

This works for me under WIN32 and linux, perl 5.6.0. 

C:\>type test.pl
#!/usr/bin/perl

use strict;
use warnings;
use diagnostics;

open  (OUTPUTFILE, ">./file.txt") || die "Oops $!";
my $tmp_dir = "foo";
my $dir = "bar";

if ($tmp_dir ne $dir) {
    print OUTPUTFILE "\n" . $tmp_dir . "\n";
    $dir = $tmp_dir;
}

close OUTPUTFILE;

C:\>perl test.pl

C:\>type file.txt

foo

C:\>

The only way I could reproduce the error you describe is to
do this (ie put in a != in place of ne):

C:\>type test.pl
#!/usr/bin/perl

use strict;
use warnings;
use diagnostics;

open  (OUTPUTFILE, ">./file.txt") || die "Oops $!";
my $tmp_dir = "foo";
my $dir = "bar";

if ($tmp_dir != $dir) {
    print OUTPUTFILE "\n" . $tmp_dir . "\n";
    $dir = $tmp_dir;
}

close OUTPUTFILE;

C:\>perl test.pl
Argument "foo" isn't numeric in numeric ne (!=) at test.pl line 11 (#1
+)

    (W numeric) The indicated string was fed as an argument to an oper
+ator that
    expected a numeric value instead.  If you're fortunate the message
    will identify which operator was so unfortunate.


C:\>

If you genuinely have ne I suspect your perl may be broken!!

If you have ne in the above code perl is quite happy even
if both the vars *are actually numeric* vis:

C:\>type test.pl
#!/usr/bin/perl

use strict;
use warnings;
use diagnostics;

open  (OUTPUTFILE, ">./file.txt") || die "Oops $!";
my $tmp_dir = 2;
my $dir = 1;

if ($tmp_dir ne $dir) {
    print OUTPUTFILE "\n" . $tmp_dir . "\n";
    $dir = $tmp_dir;
}

close OUTPUTFILE;

C:\>perl test.pl

C:\>

Note that this runs quite happily. Perl stringifies the 
numeric values in $tmp_dir and $dir for ne to use.

Because the behavior you describe is not repeatable, and should
not logically occur as perl should be automatically stringifying
the values in $tmp_dir and $dir if required I suggest you may have
a corrupt perl binary. It does happen.


I agree that use strict; use warnings; and use diagnostics;
may help. Unfortunately if you have a big script that was not 
written under use strict you will have a lot of tweaking to do 
yo get it to run (mostly declaring your variables with my), 
but other stuff too.

Good luck

Suggest testing on another box to test dud perl hypothesis


tachyon
[download]

#!/usr/bin/perl -w

$fileOUT = "mp3list.txt";
open(OUTPUTFILE,">$fileOUT");

$filename = "A02.txt";
&parseDown;

$filename = "A03.txt";
&parseDown;

$filename = "A04.txt";
&parseDown;

$filename = "A05.txt";
&parseDown;

$filename = "A06.txt";
&parseDown;

$filename = "A07.txt";
&parseDown;

$filename = "A08.txt";
&parseDown;

$filename = "A09.txt";
&parseDown;

$filename = "A10.txt";
&parseDown;


close(OUTPUTFILE);

sub parseDown {
    open(INPUTFILE,"$filename");
    
    $dir = "";

    while(($line = <INPUTFILE>) != null) {
        $line =~ m%(.*)\\(.*)%;
        $tmp_dir = $1;
        $line = $2;

        if ($tmp_dir ne $dir) {
            print OUTPUTFILE "\n" . $tmp_dir . "\n";
            $dir = $tmp_dir;
        }
        chomp($line);
        print OUTPUTFILE "\t" . $line . "\n";    
    }
    close(INPUTFILE);
}
[download]

Paul van Dyk\Seven Ways\01 Home
Paul van Dyk\Seven Ways\02 Seven Ways
Paul van Dyk\Seven Ways\03 Heaven
Paul van Dyk\Seven Ways\04 I Like It
Paul van Dyk\Seven Ways\05 Come (and Get It)
Paul van Dyk\Seven Ways\06 Forbidden Fruit
Paul van Dyk\Seven Ways\07 Beautiful Place
Paul van Dyk\Seven Ways\08 People
Paul van Dyk\Seven Ways\09 The Greatness of Britain
Paul van Dyk\Seven Ways\10 I Can't Feel It
Paul van Dyk\Seven Ways\11 Words
[download]

Two things: (1) the error message says you're trying to treat a string as a number. ne tests for unequal *strings*, while != tests for unequal *numbers*.

Perl (which, as you're finding out, is Not Java =) provides the defined() function to test for null values. So write that as

while (defined ( my $line = <INPUT>) ) {
[download]

Actually, go ahead and try

while ($line = <INPUT>) {
[download]

as even blank lines contain newlines, and so evaluate to true.

(2) it makes more sense to write parseDown¹ as a subroutine that accepts $filename as an argument than as something that expects a global to be set. Here it's not causing problems but it's not a good design to use in any script you'll keep (or cadge code from!).

sub parseDown {
  my $filename = shift @_; # or $_[0] or just plain shift
  # rest of sub
}
[download]

(3) use strict and warnings (-w in pre-5.6.0 Perl). Doing this will require that you declare your variables with my² and pay attention to scope. This is a Good thing.

(4) don't blindly use $1 and $2 without checking to see whether your regex matched. If it doesn't weird things can happen. Instead, do this:

if (my ($tmp_dir, $file) = $line =~ m%(.*)\\(.*)% ) {
    # do the rest of the stuff
} else {
    warn "$line has incorrect format!\n";
}
[download]

(5) I can't count.

HTH

¹ That spelling, and the != null test, suggest you're coming from a Java background. Apologies if that's incorrect.
²(update) or our (5.6.0) or use vars. Included for completeness. Ignore this for now, I just don't want to say anything false.

wow. i actually come from a c++ background, but ive been doing _waaaaayyy_ too much java lately. good call. :) i cant believe i forgot that i use "defined" and not testing to see if it's != null....but i did, and we all make mistakes. ;-) anyways, thanks for the mini-lesson on standards and proper coding techniques -- i seriously lack these in perl, and i really need to start learning them.

anyways, thanks a lot for your help, it was exactly what i needed!

justin