• Poor division of work. Input, processing and output are all intermixed.

• You have two vars named @bak. One's never used, the other is declared before it should be.

• You only ever put one element in the array @bak. Maybe you shouldn't be using an array.

• The whole point of using File::Find was to avoid using the shell. But then you go and pass filenames to the shell without converting them to shell literals first. That's buggy. The most common failure is that it won't delete the files you intend to delete. (Consider a file with a space in its name.) It could also delete files you did not intend to delete, and it can even execute arbitrary commands. Worst case, imagine if someone created a file named "; rm -rf ~ ; .bak". You can use the multi-argument form of system to avoid the shell, or you could use unlink.

use strict;
use warnings;

use File::Find qw( find );

my $search_dir = '/emc/cccadm/scripts/perl/etc-test';

{
    print "Are you sure you would like to delete all *.bak ".
          "files that exist in: $search_dir [yes/no] ";
    chomp( my $answer = lc(<STDIN>) );
    if ($answer ne 'y' && $answer ne 'yes') {
        die("You did not enter [yes]. Exiting program.\n");
    }

    my @bak = find_bak_files($search_dir);

    if (!@bak) {
        # Why is this worthy of being said?
        warn("No files were found\n");
    }

    for (@bak) {
        unlink($_)
            or warn("Can't delete $_: $!\n");
    }
}

sub find_bak_files {
    my ($dir) = @_;
    my @bak;
    find( sub {
        push @bak, $File::Find::name
            if /\.bak\z/ && -f;
    }, $dir);
    return @bak;
}
[download]

If it wasn't for the useless warning, you could shorten the above to

use strict;
use warnings;

use File::Find qw( find );

my $search_dir = '/emc/cccadm/scripts/perl/etc-test';

{
    print "Are you sure you would like to delete all *.bak ".
          "files that exist in: $search_dir [yes/no] ";
    chomp( my $answer = lc(<STDIN>) );
    if ($answer ne 'y' && $answer ne 'yes') {
        die("You did not enter [yes]. Exiting program.\n");
    }

    exit(1) if !delete_bak_files($search_dir);
}

sub delete_bak_files {
    my ($dir) = @_;
    my $success = 1;
    find( sub {
        if (/\.bak\z/ && -f) {
            if (!unlink($_)) {
                warn("Can't delete $File::Find::name: $!\n");
                $success = 0;
            }
        }
    }, $dir);
    return $success;
}
[download]

The first thing that leaps out from your code is the example you were give uses push to add each item to the array whereas you just assign a different single element list to the array each time around. Also, consider using unlink to remove your files and check for success.

find(sub{
  print("$File::Find::name: ",
        unlink() ? "success" : "failure ($!)"
  ) if /\.bak\z/;
}, $searchdir);
[download]

It's traditional to only be silent on success, and display errors on STDERR. It would also be useful to say what failed.

find(sub{
  if (/\.bak\z/ && -f) {
     unlink()
        or warn("Can't delete $File::Find::name: $!\n");
  }
}, $dir);
[download]

Personally, I'd print everything, save to a file, and grep for errors; assuming this is a "manual" deletion, not part of a bigger project.

You could do it this way, it won't be harmful as unlink won't delete directories so it will always be a file that ends with .bak extension.

unlink glob '/emc/cccadm/scripts/perl/etc-test/*.bak';
[download]

That's not recursive like the OP's code. It also limits the ability to report errors when you pass more than one file name to unlink.