You have to visit every value in order to determine if a certain value exists. We're talking about a pair of nested loops since your data structure has two levels.

To find the first match:

my $gene_to_find = 'NP_012';
my $matching_taxon;
TAXON:
for my $taxon (keys %gg) {
    for my $gene ( @{ $gg{$taxon} } ) {
        if ($gene eq $gene_to_find) {
            $matching_taxon = $taxon;
            last TAXON;
        }
    }
}

if (defined($matching_taxon)) {
   print("Gene $gene_to_find found in taxon $matching_taxon.\n");
} else {
   print("Gene $gene_to_find not found in any taxon.\n");
}
[download]

To find the all matches:

my $gene_to_find = 'NP_012';
my @matching_taxons;
for my $taxon (keys %gg) {
    for my $gene ( @{ $gg{$taxon} } ) {
        if ($gene eq $gene_to_find) {
            push @matching_taxons, $taxon;
        }
    }
}

if (@matching_taxons) {
   print("Gene $gene_to_find found in taxons @matching_taxons.\n");
} else {
   print("Gene $gene_to_find not found in any taxon.\n");
}
[download]

If you do many such searches between changes to %gg, you should build a hash of taxons by gene from your hash of genes by taxons.

As always, ikegami provides a clear (and clearly explained), effective solution.

Here's another approach that has the advantage of a bit more concision (I doubt it will actually run any faster), but the drawback that it uses some Perl idioms that may be unfamiliar to the programmer/maintainer. You can leave out the  defined test if you're absolutely sure a 'gene' will never be anything that looks false to Perl. (A similar problem, unaddressed, exists for the taxons.)

>perl -wMstrict -le
"use List::Util qw(first);
 my %gg = (
   1567 => [ qw(NP_011  NP_012  NP_013  NP_025)         ],
   2000 => [ qw(NP_020  NP_021  NP_024  NP_025  NP_035) ],
   9999 => [ qw(NP_900  NP_910  NP_902  0)              ],
   9998 => [],
   );
 SEARCH:
 for my $gene_to_find (qw(NP_011  NP_025  NP_999  0)) {
   print qq{searching for gene '$gene_to_find':};
   my $matching_taxon =
     first { defined first { $_ eq $gene_to_find } @{ $gg{$_} } }
     keys %gg
     ;
   my @all_matching_taxons =
     grep { defined first { $_ eq $gene_to_find } @{ $gg{$_} } }
     keys %gg
     ;
   print qq{  NOT found} and next SEARCH if not $matching_taxon;
   print qq{  first found: '$matching_taxon'};
   my $all_found = join q{' '}, @all_matching_taxons;
   print qq{  all found: '$all_found'};
   }
"
searching for gene 'NP_011':
  first found: '1567'
  all found: '1567'
searching for gene 'NP_025':
  first found: '2000'
  all found: '2000' '1567'
searching for gene 'NP_999':
  NOT found
searching for gene '0':
  first found: '9999'
  all found: '9999'
[download]

See List::Util.

One minor niggle, your results wording, "first found", implies some ordering in the hash which isn't there. Add some more data to the hash and you may well get a different "first found". If perhaps the taxon codes are all numeric and you said

... sort { $a <=> $b } keys %gg;

then the labelling would be more meaningful.

I hope this is of interest.

Cheers,

JohnGG

BariD, these are the type of questions that I have and am very glad you asked them!
ikegami, thanks for posting a very clear answer.