Load the master file into a hash; read the temp file line-by-line and check for existance; compile report.

sub load {
    my ($qfn) = @_;
    open(my $fh, '<', $qfn)
        or die("Can't open file \"$qfn\": $!\n");
    
    my %data;
    local *_;
    while (<$fh>) {
        my ($id) = /^(\S+)/ or next;
        die("Duplicate key $id\n")
            if exists($data{$id});
        $data{$id} = $_;
    }

    return \%data;
}

my $master = eval { load(...) }
    or die("Can't load master db: $@");

my $new = eval { load(...) }
    or die("Can't load new db: $@");

my %ids;
for my $id (keys(%$master), keys(%$new)) {
    next if $ids{$id}++;
    if (!exists($new->{$id})) {
        print("-$master->{$id}");
    }
    elsif (!exists($master->{$id})) {
        print("+$new->{$id}");
    }
    elsif ($master->{$id} ne $new->{$id}) {
        print("-$master->{$id}");
        print("+$new->{$id}");
    }
    else {
        print("=$master->{$id}");
    }
}
[download]

Update: Added missing parens and fixed var name as per reply.

Looks interesting, what local *_; actually does in this code?

BTW, There are few missing brackets & $keys{$id}++ meant to be $ids{$id}++ in your code right below the for loop.

while (<...>)
[download]

is short for

while (defined($_ = <...>))
[download]

local *_; prevents the clobbering of the parent's $_. my $_; would also do the trick in Perl 5.10+

Thank you very much Monks! Another question, If I have two .txt files, how do I pass the files into the program? I'm new to Perl and programming.

Command line arguments are provided via @ARGV

Hi and welcome.

So you have a list of what you want. But you didn't specify what you expect from the monks exactly.

What's the code you have so far? Where do you have problems?

2. Compare the temp file lines master file line to see if each line is present and matches.

See Printing Line Numbers in output file for a similar discussion...