Kirche has asked for the wisdom of the Perl Monks concerning the following question:

Using perl built-in threads i can write something like this: 
my @threads = ();
for(0..4)
{
    $threads[$_] = threads->create(\&func)
}
for(@threads)
{
    $_->join
}

[download]
And get 5 working threads. How to write similar code using Coro (http://search.cpan.org/~mlehmann/Coro-5.21/)?

Replies are listed 'Best First'.
Re: Coro threads
by rcaputo (Chaplain) on Feb 02, 2010 at 21:56 UTC

    Be aware of the differences between Coro and threads. Most importantly, Coro is cooperative threads. Only one CPU is used. If any coroutine blocks, so does the entire program. 

    use strict;
use warnings;
use 5.010;

use Coro;
my @threads;
for my $t ( 1 .. 3 ) {
  push @threads, async {
    print "coro $t says hi $_\n" for 1..3;
  };
}
for (@threads) {
  $_->join;
}

    [download]
    ... prints ... 
    coro 1 says hi 1
coro 1 says hi 2
coro 1 says hi 3
coro 2 says hi 1
coro 2 says hi 2
coro 2 says hi 3
coro 3 says hi 1
coro 3 says hi 2
coro 3 says hi 3

    [download]

    Coro has a yield() call which can be used to interleave coroutines. However, libraries that don't call yield() or use other Coro facilities can still block everything.

    Also, yield() doesn't involve additional CPUs, so cpu-intensive programs may benefit more from threads or fork().

    --
    Rocco Caputo - http://poe.perl.org/ - irc://irc.perl.org/poe

[reply]
[d/l]
[select]
Re: Coro threads
by zwon (Abbot) on Feb 02, 2010 at 21:18 UTC 
    use strict;
use warnings;
use 5.010;

use Coro;
my @threads;
for ( 1 .. 5 ) {
    push @threads, async {
        say "Hi!";
    };
}
for (@threads) {
    $_->join;
}

    [download]
[reply]
[d/l]
Re: Coro threads
by ikegami (Patriarch) on Feb 02, 2010 at 22:57 UTC
    Coro provides cooperative multitasking. Your code relies on a preemptive multitasking system. You can't create preemptive multitasking system from a cooperative multitasking system.
[reply]

Back to Seekers of Perl Wisdom