in reply to Re^2: Perl Tk freezes when command button is clicked !
in thread Perl Tk freezes when command button is clicked !

Your problem is a common one, in all gui toolkits, it's called "blocking the event loop". All gui's use an event loop, that is why they can be responsive to button clicks, etc. When you put a sleep statement, or do something which is long and intensive like getting a url thru a slow netlink, the event loop will freeze until it regains control. This can be shown is the following example. After 2.5 seconds, it will freeze for 5 seconds 
#!/usr/bin/perl
use Tk;

my $mw = MainWindow->new;
$mw->geometry('100x100+100+100');
#$mw->overrideredirect(1);

my @color = qw/red green/;

my $bits = pack("b8"x8,
"...11...",
"..1111..",
".111111.",
"11111111",
"11111111",
".111111.",
"..1111..",
"...11...",);

$mw->DefineBitmap('indicator' => 8,8, $bits);

my $label = $mw->Label(
              -bitmap=>'indicator', 
          -bg=>'black',
          -fg=>'red',
          )->pack;

$mw->repeat(500,sub{$label->configure(
                               -fg=>$color[0]);
                               @color=reverse(@color);
 });


# put in simulated eventloop blocker after 2.5 seconds
# to freeze tk for 5 seconds
$mw->after(2500,sub{ sleep (5)  });

MainLoop;

[download]
There are many ways around this problem. First never use sleep in a gui app, unless it's in a thread. Second, put your url_fetching operations into threads or fork them off. You can try to manually pump the loop by liberally sprinkingly DoOneEvent(); in areas where the code is in a delay loop( like your in while( $fh ). Finally, use Tk::fileevent to read your filehandles, instead of a while loop. Use timers when needing delays, like Tk::repeat.

There are many examples out there on google for using Tk with threads and shared variables. See Tk events by Lidie and a few examples of using threads and fileno's with Tk ztk-BBC-World-News-Rss-TickerTape and Re^3: Passing globs between threads

I'm not really a human, but I play one on earth.
Old Perl Programmer Haiku

Replies are listed 'Best First'.
Re^4: Perl Tk freezes when command button is clicked !
by mykl (Monk) on Feb 17, 2010 at 15:03 UTC

    As an alternative to using threads, it is also possible to unblock the event loop by manually calling $mw->update() at frequent intervals to alllow the GUI to update, respond etc. This may or may not be easier/better for you, depending on what you are trying to do. I think it doesn't matter what Tk object you call the update() method on, although I usually use the main window.

    --

    "Any sufficiently analyzed magic is indistinguishable from science" - Agatha Heterodyne

[reply]
[d/l]
[select]
      The problem with using $mw->update or DoOneLoop() is that they still will block on slow network calls that are sluggish. When you use $lwp->get( $url), there is no place to insert the update, unless you use the more extended manual callback available in lwp, as shown in 
      #!/usr/bin/perl -w
use strict;
use LWP::UserAgent;

# don't buffer the prints to make the status update
$| = 1;

my $ua = LWP::UserAgent->new();
my $received_size = 0;
my $url = 'http://www.cpan.org/authors/id/J/JG/JGOFF/parrot-0_0_7.tgz'
+;
print "Fetching $url\n";
my $request_time = time;
my $last_update = 0;
my $response = $ua->get($url,
                        ':content_cb'     => \&callback,
                        ':read_size_hint' => 8192,
                       );
print "\n";

sub callback {
  my ($data, $response, $protocol) = @_;

  my $total_size = $response->header('Content-Length') || 0;
  $received_size += length $data;

  my $time_now = time;

  # this to make the status only update once per second.
  return unless $time_now > $last_update or $received_size == $total_s
+ize;
  $last_update = $time_now;

  print "\rReceived $received_size bytes";
  printf " (%i%%)", (100/$total_size)*$received_size if $total_size;
  printf " %6.1f/bps", $received_size/(($time_now-$request_time)||1)
     if $received_size;
}

      [download]
      If you don't put your update calls into that callback, it will still block Tk until the get returns. And if the get() hangs, your Tk program could be hung forever, unless you set timers on it.

      But it really is easier just to use a thread. :-)

      I'm not really a human, but I play one on earth.
      Old Perl Programmer Haiku
[reply]
[d/l]
Re^4: Perl Tk freezes when command button is clicked !
by Anonymous Monk on Feb 17, 2010 at 15:31 UTC
    always i love your code zentara ; it is lucid and educational
    thanks
[reply]

In Section Seekers of Perl Wisdom