Re^3: Best practices - if any? (our)

Variables declared with our create a package variable and a lexically scoped ~~variable which is an~~ alias to that package variable, visible through the entire scope (file or block) even spanning packages:

# file foo.pl
use strict;
our $foo; # that's $main::foo

{
    package Foo;
    our $foo = "foo"; # package variable $Foo::foo created
    print __FILE__,' ',__LINE__,' ',__PACKAGE__,":: \$foo is '$foo'\n"
+;

    package Bar;
    print __FILE__,' ',__LINE__,' ',__PACKAGE__,":: \$foo is '$foo'\n"
+;
}
print __FILE__,' ',__LINE__,' ',__PACKAGE__,":: \$foo is '$foo'\n";
print __FILE__,' ',__LINE__,' ',__PACKAGE__,":: \$Foo::foo is '$Foo::f
+oo'\n";
[download]

# file bar.pl
use strict;

{
    package Bar;
    our $foo; # package variable $Bar::foo created
    print __FILE__,' ',__LINE__,' ',__PACKAGE__,":: \$foo is '$foo'\n"
+;
} # end of scope

package Foo;
our $foo; # package variable $Foo::foo initialized in 'foo.pl'
print __FILE__,' ',__LINE__,' ',__PACKAGE__,":: \$foo is '$foo'\n";

package Bar;
print __FILE__,' ',__LINE__,' ',__PACKAGE__,":: \$foo is '$foo'\n";
[download]

#!/usr/bin/perl

use strict;
our $foo = 'bar'; # package variale main::foo
require 'foo.pl';
require 'bar.pl';

print __FILE__,' ',__LINE__,' ',__PACKAGE__,":: \$foo is '$foo'\n";
[download]

Running main.pl yields

foo.pl 8 Foo:: $foo is 'foo'
foo.pl 11 Bar:: $foo is 'foo'
foo.pl 13 main:: $foo is 'bar'
foo.pl 14 main:: $Foo::foo is 'foo'
bar.pl 7 Bar:: $foo is ''
bar.pl 12 Foo:: $foo is 'foo'
bar.pl 15 Bar:: $foo is 'foo'
main.pl 8 main:: $foo is 'bar'
[download]

updated as per JavaFan's comment below. Of course there's only one variable and it's alias in the current scope.

Comment on Re^3: Best practices - if any? (our) Select or Download Code

Replies are listed 'Best First'.
Re^4: Best practices - if any? (our) by JavaFan (Canon) on Feb 22, 2010 at 11:43 UTC
Variables declared with our create a package variable and a lexically scoped variable That suggests any use of `our` creates two variables. It doesn't. It creates an alias (another name) for the variable - the alias is lexically scoped. And no matter how many times you use `our`, it doesn't create new variables over and over again - unlike my. `my $foo++; say $foo; my $foo++; say $foo; our $bar++; say $bar; our $bar++; say $bar; __END__ 1 1 1 2` [download] It does warn. But even if you put all the lines in different scopes (no warnings then), it's still the same variable when using `our`: `{my $foo++; say $foo;} {my $foo++; say $foo;} {our $bar++; say $bar;} {our $bar++; say $bar;} __END__ 1 1 1 2` [download]	[reply] [d/l] [select]
Re^5: Best practices - if any? (our) by shmem (Chancellor) on Feb 22, 2010 at 12:49 UTC
But even if you put all the lines in different scopes (no warnings then), it's still the same variable when using our: ...as long as the alias refers to the same package variable. An our in an inner scope creates a new alias: `our $foo; { our $foo = 'foo'; say $foo; } { package Foo; our $foo = 'bar'; say $foo; } package main; say $foo; package Foo; say $foo; { package Foo; our $foo; say $foo; { package Bar; our $foo = 'quux'; say $foo; } say $foo; } { package Foo; say $foo; } __END__ foo bar foo foo bar quux bar foo` [download]	[reply] [d/l]