Here's a reformed version. Your main problem seemed to be the extra increment of $i down at the bottom. There is no reason to do this with a loop if you already know the position so I removed it and inlined one of the subs. Give it a shot.

use warnings;
use strict;

my $seq = 'AAAAAAAAAAAAAAAAAAAAAAAAAAAAAA';
print "The DNA sequence is : $seq\n";

mutate($seq);

exit;

sub mutate {
    my $dna = shift;
    my $position = int(rand(length($dna)));

    print " mutation at  base position ". ($position+1) . "\n";

    my $nucleotide;
    do {
        $nucleotide = randombase();
    } until ( $nucleotide ne substr($dna,$position,1) );

    substr($dna, $position, 1, $nucleotide);
    print "$dna\n";
}

sub randombase {
    my ( @nucleo ) = qw ( A T C G );
    return $nucleo[rand(@nucleo)];
}
[download]

Your problem is with the for loop:

for ($i =0;$i<length($dna);$i++){

    if ($i == $position){

print " mutation at  base position ". ($position+1) . "\n";
    do {
    $nucleotide = randombase();

     } until ($nucleotide ne substr($dna,$position,1));
    substr($dna, $position, 1, $nucleotide);

    print "$dna\n";
    }
$i++;
}
[download]

You increment $i at the top of the loop and at the bottom of the loop so sometimes $i will never be equal to $position.

Better to write the loop as:

for my $i ( 0 .. length( $dna ) - 1 ) {
[download]

Also, you don't need a do block for your until statement modifier:

    $nucleotide = randombase() until $nucleotide ne substr $dna, $posi
+tion, 1;
[download]

1. You do not need the for loop at all, you are merely counting to 30 and doing something once when you reach a magic number. This is particularly true if the starting dna sequence is greater than 30 bases.
2. A look up table would be faster then an "until we get a different answer", this is particularly true if you are going to mutate your starting sequence repeatedly.

#!/usr/bin/perl 

use strict;
use warnings;

print "The DNA sequence is : \n" ;
my $seq = 'AAAAAAAAAAAAAAAAAAAAAAAAAAAAAA';

print "$seq \n";
mutate ($seq);
exit;

sub mutate{
        my($dna) = shift;
        my $position = randposition($dna);
        print " mutation at  base position ". ($position+1) . "\n";
        my $nucleotide = randombase(substr($dna,$position,1));
        substr($dna, $position, 1, $nucleotide);
        print "$dna\n";
}

sub randposition{
        my($sequence) = @_;
        return int rand length($sequence);
}

sub randombase{
        my $base=shift;
        my(%nucleo)=(   'A'=>['T','C','G'],
                        'T'=>['A','C','G'],
                        'C'=>['A','T','G'],
                        'G'=>['A','T','G'],
                    );
        return $nucleo{$base}[rand(@{$nucleo{$base}})];
}
[download]

Utilitarian:

++ for removing the loop. I had a thought about your randombase routine, though. I came up with:

sub randombase {
    # Prevent us from returning the same symbol
    my @list = grep { $_ ne $_[0] } @symbols;

    return $list[rand(@list)];
}
[download]

...roboticus