use strict;
use warnings;

my $text = join '', <DATA>;
my %replacements = (
    'Romeo'  => 'CountZero',
    'Juliet' => 'Elisabeth',
    'Rom.'   => 'CountZero',
    'Jul.'   => 'Elisabeth',
    'Abram'  => 'Igor',
    'Abr.'   => 'Igor',
);
$text =~s/(Romeo|Juliet|Rom\.|Jul\.|Abram|Abr\.)/$replacements{$1}/gi;

print $text;

__DATA__

(follows the full Project Gutenberg e-text of Shakespeare's Romeo and 
+Juliet; found at http://www.gutenberg.org/dirs/etext97/1ws1610.txt)
[download]

You're right on the money!!
Couldn't be more precise!!


You're way of solution realy amazed me. Thank you very much.

PS: I loved your Geoffrey James quotation too!

There is a gotcha with the solution as written (well, several actually) - you need to provide every possible (or at least likely) case variation for each of the matched words. Combining the special markup you have alluded to elsewhere with the e flag for the regex gives a somewhat more robust solution:

use strict;
use warnings;

my $text = join '', <DATA>;
my %replacements = (
    'romeo'  => 'CountZero',
    'juliet' => 'Elisabeth',
    'rom.'   => 'CountZero',
    'jul.'   => 'Elisabeth',
    'abram'  => 'Igor',
    'abr.'   => 'Igor',
);
$text =~s/%%([^%]+)%%/replace($1)/ge;

print $text;


sub replace {
    my ($needle) = @_;

    return "%%$needle%%" if ! exists $replacements{lc $needle};
    return $replacements{lc $needle};
}


__DATA__
(follows the full Project Gutenberg e-text of Shakespeare's %%Romeo%% 
+and %%Juliet%%;
found at http://www.gutenberg.org/dirs/etext97/1ws1610.txt)
[download]

Prints:

(follows the full Project Gutenberg e-text of Shakespeare's CountZero 
+and Elisabeth;
found at http://www.gutenberg.org/dirs/etext97/1ws1610.txt)
[download]

---

True laziness is hard work

use Text::Template;

my $template = Text::Template->new(
    type => "FILEHANDLE",
    source => *DATA,
);

my $text = $template->fill_in(
    hash => {
        placeholder1 => "chicken",
        placeholder2 => "dog",
    },
);

print $text;

__END__
This is text with { $placeholder1 }.
It can be with { $placeholder2 } too.
{ $placeholder1 } can appear more than one time in the text.
[download]

Aw come on! Don't spoil it for the OP.

Reinventing a web-framework or a templating system must be one of the rites of passage of becoming a real Perl programmer.

;-)

CountZero

A program should be light and agile, its subroutines connected like a string of pearls. The spirit and intent of the program should be retained throughout. There should be neither too little or too much, neither needless loops nor useless variables, neither lack of structure nor overwhelming rigidity." - The Tao of Programming, 4.1 - Geoffrey James

Do you mean something like

or is each unique placeholder to be replaced by a unique replacement? (and what is the "needls/" in your narrative?)

On asking for help and How do I post a question effectively? and you may also want to search for "I know what I mean..."

needles is a synonim for placeholders.

Each placeholder has a unique replacement.
The text can be like the following


This is text with %%placeholder1%%.
It can be with %%placeholder2%% too. %%placeholder1%% can appear more than one time in the text.

My intention is to replace them with my replacements at one line and not to loop on the placeholders and replace them one by one.

There are discussions of various different approaches to some similar problems on the long and winding threads starting at Interpolating backreferences in an eval and by way of Re: Interpolating backreferences in an eval.