I took the freedom to slightly simplify your spec, using a lookup table. The output should be what I suppose you want, i.e. replace all occurrences of c1 etc. with c1 d1 etc.:

#!/usr/bin/perl
use strict;
use warnings;

my $fname_A     = "file_A.txt";
my $fname_B     = "file_B.txt";
my $fname_B_out = "file_B_out.txt";

my %subst;  # lookup table

open (my $data_fh, "<", $fname_A) or die "Couldn't open '$fname_A': $!
+";
while (<$data_fh>) {
    chomp;
    my ($find, $add) = (split /\t/)[2,3];
    $subst{$find} = $add;
    # print "$find => $add\n";  # debug
}

my $search = join "|", map quotemeta, keys %subst;

open (my $in_fh,  "<", $fname_B)     or die "Couldn't open '$fname_B':
+ $!";
open (my $out_fh, ">", $fname_B_out) or die "Couldn't open '$fname_B_o
+ut' for writing: $!";
while (my $line = <$in_fh>) {
    $line =~ s/($search)/$1 $subst{$1}/g;
    print $out_fh $line;
}
[download]

The output might not be what you want in case the search strings aren't unique (because of the lookup hash), or if the substitutions aren't independent, such as when c1 => c2 in the first run through the file, c2 => d2 in the second run, etc. (because of doing it all in one go).

First a few suggestions:

• Always use strictures (use strict; use warnings;)
• use the three parameter version of open and always check the result.
• use lexical file handles (declared with my)
• use the Perl version of the for loop, not the C version
• avoid opening and closing the same file multiple times

#!/usr/bin/perl
use strict;
use warnings;

# Fake up a couple of files
my $file_a = <<TXT;
a1\tb1\tc1\td1
a2\tb2\tc2\td2
a3\tb3\tc3\td3
TXT
my $file_b = <<TXT;
starting form the top of the file I need 1. to get the the value in th
+e 3rd
column (c1)

2. search in a second file (file_B.txt, not tab delimited and quite me
+ssy) all
the matches for it.

3. when a match is found, I would like to append to the current value 
+(c1), the
value of 4th column (d1) in file_A.txt, separated by a space.

4. go back to the first file (file_A.txt), get the the value in the 3r
+d column
in the second row (c2) and do another round of search and insert the v
+alue of d2
in the second file (file_B.txt).
TXT

# Now the 'real' work - \$file_b treats $file_b as a file
open my $inB, '<', \$file_b or die "Can't open file_b: $!";
my $fileBStr = do {local $/; <$inB>}; # Slurp in all of file_b
close $inB;

open my $inA, '<', \$file_a or die "Can't open file_a: $!";

while (<$inA>) {
    chomp;
    
    my @parts = split /\t/;
    
    next if @parts < 4;
    
    $fileBStr =~ s/\b $parts[2] \b/$parts[2] $parts[3]/xgm;
}

close $inA;

print $fileBStr;
[download]

Prints:

starting form the top of the file I need 1. to get the the value in th
+e 3rd
column (c1 d1)

2. search in a second file (file_B.txt, not tab delimited and quite me
+ssy) all
the matches for it.

3. when a match is found, I would like to append to the current value 
+(c1 d1), the
value of 4th column (d1) in file_A.txt, separated by a space.

4. go back to the first file (file_A.txt), get the the value in the 3r
+d column
in the second row (c2 d2) and do another round of search and insert th
+e value of d2
in the second file (file_B.txt).
[download]

Reading the file you are editing into memory is fine unless its size is hundreds of megabytes. For very large files you probably need to turn the loop inside out - read all the edit information from file a and store that in memory, then read file b a line at a time and apply all the edits to the current line before saving it and moving on to the next.

use strict;
use warnings;

my $fhi;

my %data;
open $fhi, '<', 'file_A.txt' or die "can not open file file_A.txt: $!"
+;
while (<$fhi>) {
    chomp;
    my @cols = split /\t/;
    $data{$cols[2]} = "@cols[2..3]";
}
close $fhi;

open    $fhi, '<', 'file_B.txt'     or die "can not open file file_B.t
+xt: $!";
open my $fho, '>', 'file_B_out.txt' or die "can not open file file_B_o
+ut.txt: $!";
while (<$fhi>) {
    for my $k (keys %data) {
        s/$k/$data{$k}/g;
    }
    print $fho $_;
}
close $fho;
[download]

Update: I like almut's $search string better than my for loop.

Dear all,

thanks for your suggestions. I will need little bit to "digest" your suggestions.

1. GrandFather: I have hard time telling apart your suggested code form some of the comments. I will try to disentangle the thing and get back to you.

2. I tried the code from almut. It works but it will not distinguish between c1 and c11. In other words when C11 is found d1 is added within the 11. The final result is "c1 d11"

3. I will take a look at toolic suggestion later

Thanks for your help.

2. I tried the code from almut. It works but it will not distinguish between c1 and c11. In other words when C11 is found d1 is added within the 11. The final result is "c1 d11"

My solution also does not distinguish between c1 and c11. You can add \b anchors, as GrandFather has (see perlre):

        s/\b$k\b/$data{$k}/g;
[download]