in reply to Re: IPC::Open3 woes
in thread IPC::Open3 woes

I am hopeing that somebody can add some clarity to this old thread. Can somebody tell me why the following coded hangs if the line which defines the @outlines array is commented out?

I have used open3 in other places w/o reading the the child's output and the process didn't hang. I expect it is because in that case the command didn't have output.

I understand how some of the other example programs in this thread prevent locking while read from open3's handles but it seems strange that this would lock when I am not reading from them and just calling waitpid as soon as possible.

Also, should I explicitly close $wtr, $rtr, and $err?

...
my($wtr,$rdr);
my $err = gensym;

### $logcmd is a command that returns approx. 460 lines.
my $pid = open3($wtr, $rdr, $err, "$logcmd");
my @outlines = <$rdr>;  ### if this line is commented out we hang on w
+aitpid
waitpid( $pid, 0 );
...

[download]

Replies are listed 'Best First'.
Re^3: IPC::Open3 woes
by ikegami (Patriarch) on Apr 21, 2010 at 23:36 UTC

    I am hopeing that somebody can add some clarity to this old thread. Can somebody tell me why the following coded hangs if the line which defines the @outlines array is commented out?

    You have a deadlock.

    • waitpid never returns because the child never exits.
    • The child never exits because it's blocked trying to write a full pipe.
    • The pipe is full because noone is emptying it.

    If it doesn't happen for all your children, it's because they don't output enough data to fill the pipe. 

    use strict;
use warnings;

use IPC::Open3 qw( open3 );

for (my $size = 1024; ; $size += 1024) {
   print("$size\n");
   my $pid = open3(
      local our $to_chld,
      local our $fr_chld,
      local our $fr_chld_err,
      perl => (
         -e => 'print "x" x $ARGV[0]',
         $size
      )
   );
   waitpid($pid, 0);
}

    [download]
    ...
62464
63488
64512
65536
66560
[hangs]^C

    [download]

    The solution is to redirect the output to /dev/null 

    use strict;
use warnings;

use IPC::Open3 qw( open3 );

open(local *DEVNULL, '>', '/dev/null') or die;

for (my $size = 1024; ; $size += 1024) {
   print("$size\n");
   my $pid = open3(
      local our $to_chld,
      '>&DEVNULL',
      '>&DEVNULL',
      perl => (
         -e => 'print "x" x $ARGV[0]',
         $size
      )
   );
   waitpid($pid, 0);
}

    [download]
    ...
365568
366592
367616
368640
369664
370688
371712
372736
373760
374784
...

    [download]
[reply]
[d/l]
[select]
Re^3: IPC::Open3 woes
by Anonymous Monk on Apr 21, 2010 at 23:04 UTC
    Please somebody do comment, this is great information. I fear it is now out of date. I can't get this to work under Perl 5.8 any more. The documentation does not help. The code hangs on the open3 call.
[reply]

In Section Seekers of Perl Wisdom