When you need to initialize an array with a range of numbers, you can use Perl's Range Operators:

my @new_lot = 1 .. 186;
[download]

It can also be used to create more Perl-ish for loops:

    for(my $o = 0;$o<6;$o++){
[download]

can also be coded as:

    for my $o (0 .. 6){
[download]

gskoli:

Just a minor suggestion on your array initialization: It looks like your data may come from a table that you manually split into three vectors. In the future, you may want to try putting the table into your code like so:

my (@new_lot, @cat_one, @A_services);
my @table = qw (
    1    R    182
    2    R    111
    3    RC   160
    4    RC   105
    5    R    113
    6    RC   121
);
[download]

Then you can split it out into separate tables (if you like) like this:

while (@table) {
    push @new_lot,    shift @table;
    push @cat_one,    shift @table;
    push @A_services, shift @table;
}
[download]

It adds a little processing time, but makes maintenance quite a bit easier. Alternatively, you can avoid the extra processing and just go ahead and make it an AoA, like this:

my @table = (
   [ qw( 1    R    182 ) ],
   [ qw( 2    R    111 ) ],
   [ qw( 3    RC   160 ) ],
   [ qw( 4    RC   105 ) ],
   [ qw( 5    R    113 ) ],
   [ qw( 6    RC   121 ) ],
);
[download]

But you'll have to change your coding a little, though, as $cat_one[2] would become $$table[2][1].

...roboticus

UPDATE: Per chromatic's fine suggestion, I changed the lines like $new_lot[@new_lot] = shift @table; to push @new_lot, it makes the code look much nicer.

while (@table) {
    $new_lot[@new_lot] = shift @table;
    $cat_one[@cat_one] = shift @table;
    $A_services[@A_services] = shift @table;
}
[download]

May I suggest push instead?

while (@table) {
    push @new_lot,    shift @table;
    push @cat_one,    shift @table;
    push @A_services, shift @table;
}
[download]

i want groups of six random no. which total of services must be in between 840 - 900 But problem is that i am getting repeating random No. & that is i don want

There are several ways to interpret that.

One way is that you want: groups of six randomly chosen, unique (positive) integers that sum to between 840 - 900 (inclusive?). Here is a sub that will do that:

#! perl -slw
use strict;
use List::Util qw[ sum ];

sub nUniqRandsSumTo {
    my( $n, $target ) = @_;
    ## Prevent infinite loop.
    die 'No solution' if ( ( $n * ($n-1) ) / 2 ) > $target;
    my @rvs;
    {
        @rvs = $target;
        while( @rvs < $n ) {
            ## pick an element at
            my $i = int rand @rvs;

            ## Can't split 0, 1, 2 into two unique values
            redo if ( my $toSplit = $rvs[ $i ] ) < 3;
            my $first = int( rand $toSplit );
            my $second = $toSplit - $first;

            ## try again if it split into two equal values
            redo if $first == $second;

            ## replace the original with the random pair
            splice @rvs, $i, 1, $first, $second;
        }
        my %seen;
        ## Do it all from scratch if we got dups
        ## Can be expensive if the target is close to the limit
        redo if grep{ ++$seen{ $_ } > 1 } @rvs;
    }
    return @rvs;
}

for( 1 .. 10 ) {
    my $target = 840 + int( rand 61 );
    my @rands = sort{ $a <=> $b } nUniqRandsSumTo( 6, $target );
    printf "sum: %3d [ %s ]\n", sum( @rands ), "@rands";
}

__END__
c:\test>834245.pl
sum: 896 [ 0 27 34 162 197 476 ]
sum: 889 [ 35 77 109 179 196 293 ]
sum: 878 [ 18 23 77 91 280 389 ]
sum: 885 [ 6 37 68 136 154 484 ]
sum: 854 [ 7 8 12 70 237 520 ]
sum: 899 [ 8 10 29 101 293 458 ]
sum: 858 [ 0 28 37 52 367 374 ]
sum: 887 [ 1 8 11 22 43 802 ]
sum: 899 [ 11 64 65 117 271 371 ]
sum: 872 [ 7 14 40 43 154 614 ]
[download]

The way it works is it picks a target between 840 & 900 and then calls the sub with N (6) and the chosen target.

The sub:

1. Places the target in an array.
2. Loops while the size of the array is less than N.
3. Picks one of the values in the array at random and splits it randomly into 2 values that add up to the original.
4. Checks for dups and starts again if it has any.

Other possible interpretations include:

• The values are not just unique within the groups of six, but also across all the groups.
• You want all unique groups of 6 (positive) numbers that sum to between your two values.
• Your target range could be inclusive; exclusive; high or low inclusive only.

Thanks ....
But the range should now not be exclude ...
In the o/p the group of no. must be in range that is we have defined that means ::: Actually The array look like this
New Lots   Serv.
1   121
2   182
3   111
4   160
5   105
6   113
7   121
8   97

Here "New Lots" having range of (186) Respected Services are given
So now i want Such "New Lots" with group of 4/5/6 in such way that it will not be repeated it will not contain zero and respected "Serv." addition must be in between 840-900

Sorry. But I do not understand this description at all. Maybe someone else will.

---

Examine what is said, not who speaks -- Silence betokens consent -- Love the truth but pardon error.

"Science is about questioning the status quo. Questioning authority".

In the absence of evidence, opinion is indistinguishable from prejudice.

RIP an inspiration; A true Folk's Guy

srand is needed only in versions of Perl before 5.004. I believe he might want to shuffle a deck of cards (ie there are only four aces, not an infinite supply).

-1, incorrect. From the rand docs you linked to:

Automatically calls srand unless srand has already been called.

There is no need to manually call srand in Perl.

Please do not make substantial changes to the content of your node without indicating that you have updated it. Doing so often invalidates replies and is prone to making monks less inclined to help.

I am sorry ,new user