Unicode defines a variety of normalization forms (see http://unicode.org/reports/tr15/).

I prefer normalization form NFKD, as it translates more ligatures (though not all, for example the ligature Œ).

First decompose composite characters into their component parts (e.g. letters and diacritical marks), then strip out the marks.

$str = Unicode::Normalize::NFKD($str);
$str =~ s/\p{NonspacingMark}//g;
[download]

## Demonstrate stripping of diacritical marks from Unicode strings
## April 2010, Bryce Nesbitt, Berkeley Electronic Press
## See also http://unicodelookup.com/
## See also http://en.wikipedia.org/wiki/Diacritic
## Keywords: perl, diacritic, diacritical
##           accent, iso-8859-1, normalization.
use utf8;                   # Tell perl source code is utf-8
use 5.10.0;
use Unicode::Normalize;

# Sample: "latin small letter e with circumflex and tilde" ễ
#         "latin small ligature ff" (will be expanded)
#         "latin small ligature oe" (won't be expanded)
$str = shift || "\x{1ec5} märks \x{fb00} \x{153}";
say "Input: ".debug_chatty_string($str);

# Decompose into letter and combining marks, in "Kompatibility" mode
$str = NFKD($str);
say "NFKD : ".debug_chatty_string($str);

# Remove combining marks
$str =~ s/\p{NonspacingMark}//g;
$str = lc($str);
say "Out  : ".debug_chatty_string($str);

sub debug_chatty_string
{
    my $outstring;
    # Use shift below, so utf-8 flag is preserved.
    # Else you might have to fiddle with Encode::_utf8_on()
    foreach $char (split //,shift) {
        my $ord = ord($char);
        if(($ord >= 32 && $ord < 127) || $ord == 10) {
            $outstring .= $char;
        } else {
            $outstring .= "<0x".sprintf("%x",$ord).">";
        }
    }
    return $outstring;
}
[download]

Input: <0x1ec5> m<0xe4>rks <0xfb00> <0x153>
NFKD : e<0x302><0x303> ma<0x308>rks ff <0x153>
Out  : e marks ff <0x153>
[download]

Update: I really do mean normalization. ASCIIfying (e.g. encoding) would destroy non-latin text. Normalization preserves Greek, Hebrew, etc.

I am supporting clients in various languages who want the fuzzy matching that stripping diacriticals provides. It might make for the occasional confusion between German bears and bars... but that's much better than missing out on all the potential correct matches. For example in Hebrew vowels are not normally written except for children. Stripping the vowel and pronunciation diacriticals out lets you compare the text as an adult searcher will likely enter it.

use strict;
use warnings;

use utf8;

use Unicode::Normalize;

my $s = "söme stüff\n";
$s = NFD($s);

$s =~ s/\pM//g;
print $s;
[download]

Depending on the application, the NFKD might or might not be more appropriate than NFD.

The code snippet above removes all marking characters, not just diacritical marks. You can change that by removing only \x{308}. The following code strips the diacritical mark, but leaves the accents:

use strict;
use warnings;

use utf8;

use Unicode::Normalize;
binmode STDOUT, ':utf8';

my $s = "söme stüff with áccènts\n";
$s = NFD($s);

$s =~ s/\x{308}//g;
$s = NFC($s);
print $s;
[download]

I don't think that this kind of "normalizing" is a good idea. In German, "Bär" und "Bar" are two very different things, and stripping a Bär doesn't make entering it more attractive.

Alexander

This (like stemming) is often done for search engines .

afoken: no, this is normalization. ASCIIfying (e.g. encoding) would destroy non-latin text. This method preserves Greek, Hebrew, etc.

Alexander: I am supporting clients in various languages who want the fuzzy matching that stripping diacriticals provides. It might make for the occasional confusion between German bears and bars... but that's much better than missing out on all the potential correct matches. For example in Hebrew vowels are not normally written except for children. Stripping the vowel and pronunciation diacriticals out lets you compare the text as an adult searcher will likely enter it.

Note that I prefer normalization form NFKD, as it translates more ligatures (though not all, for example the ligature Π)

Originally posted as a Categorized Answer.

Originally posted as a Categorized Answer.