use strict;
use warnings;
my @AoA=(
        [0, 1, 0, 0],
        [0, 0, 1, 0],
        [0, 0, 0, 1]
     );

print 'Number of rows = ', scalar @AoA, "\n";
for my $aref (@AoA) {
    print 'Number of cols = ', scalar @{$aref}, "\n";
}

__END__

Number of rows = 3
Number of cols = 4
Number of cols = 4
Number of cols = 4
[download]

See also:

• perldsc
• References quick reference

$rows= @AoA;
# more explicit:
$rows= scalar @AoA;

#only if all rows are the same size:
$columns= @{$AoA[0]}; # == no. of columns in row 0
[download]

#!/usr/local/bin/perl
use strict;
use warnings;

my @AoA=(
        [0, 1, 0, 0],
        [0, 0, 1, 0,0,0,0,0],
        [0, 0, 0, 1,0,1]
     );
 # my $row = scalar @AoA; ##Prints the number of rows for the array

for(my $i = 0; $i<=$#AoA;$i++){
        my $count =0;
        foreach my $column (@{$AoA[$i]}){
                $count ++;
                }
        print "Row# ", $i+1, " has $count columns\n";
        }
[download]

for(my $i = 0; $i<=$#AoA;$i++){
        my $count = @{$AoA[$i]};  
        print "Row #: ", $i+1, " has $count columns\n";
        }
[download]

    my $count =0;
    foreach my $column (@{$AoA[$i]}){
            $count ++;
            }
[download]

When all you do in the loop is increment, you might as well just write

    my $count = @{$AoA[$i]};
[download]

which, btw, is approximately N times faster, with N being the size of the array:

use Benchmark 'cmpthese';

my @AoA;
$AoA[42] = [ (1) x 1000 ];

cmpthese(-1,
    {
        counted => sub {
            my $count =0;
            foreach my $column (@{$AoA[42]}){
                    $count ++;
                    }
        },
        direct  => sub {
            my $count = @{$AoA[42]};
        },
    }
);

__END__
             Rate counted  direct
counted   11821/s      --   -100%
direct  9267717/s  78297%      --
[download]

Consider using Math::Matrix, especially if you're going to be doing more than just scanning the contents.

One thing that you need to bear in mind is: there is no such thing as "a multi-dimensional array per se in Perl."

Instead, you have something far more powerful:   a list of references to other lists. (Hence, the various lists do not have to be of the same length.)

The “breakthrough” is this:   that “a reference to (anything)” is always “a single thing,” no matter what it refers to at any particular moment.