When dealing with XML, it's generally easier to use pre-rolled solutions like XML::Simple or XML::Twig; however, you can accomplish your goal with character classes - note this assumes that > does not occur in string context - I don't remember what characters are valid in attribute strings:

my $string = '<image attrib="one" attrib2="two" scope="local"/>';
$string =~ s/(<image\s[^>]*?)scope="local"/$1/g;
print "$string\n";
__END__
<image attrib="one" attrib2="two" />
[download]

See perlretut for more info on character classes.

use strict;
use warnings;

use XML::Twig qw( );

binmode STDOUT;

my $t = XML::Twig->new(
   twig_handlers => {
      'image[@scope="local"]' => sub {
         $_->del_att('scope');
      },
   },
);
$t->parsefile($ARGV[0]);
$t->flush();
[download]

use strict;
use warnings;

use XML::LibXML qw( );

my $parser = XML::LibXML->new();
my $doc    = $parser->parse_file($ARGV[0]);
my $root   = $doc->documentElement();

for my $node ($root->findnodes('//image[@scope="local"]')) {
   $node->removeAttribute('scope');
}

binmode STDOUT;
print $doc->toString();
[download]

I'm not even gonna try an XML::Simple solution.

I was curious why you binmode STDOUT in your code (and in your other example) - is it to ensure you have UNIX line endings (and not CRLFs) in the output if Perl is running on Windows?

A newbie generally accepts the advice NOT to use regex to parse xml.

use strict;
use XML::Rules;
my $parser = XML::Rules->new(
  style => 'filter',
  rules => {
    _default => 'raw',
    image => sub {
      my ($tag, $attr) = @_;
      delete $attr->{scope} if $attr->{scope} eq 'local';
      return $tag => $attr;
    }
  }
);

$parser->filterfile( $input_file, $output_file);
[download]