>perl -wMstrict -le
"for (@ARGV) {
   if(/^A (?: Z | (\s.*?)) Z$/x) {
     my $grabbed = $1 // '';
     print qq{matched '$_'  grabbed '$grabbed'};
     }
   }
"  AZ  AZZ  AXZ  "A SOMETHING Z"  ASOMETHINGZ
matched 'AZZ'  grabbed ''
matched 'A SOMETHING Z'  grabbed ' SOMETHING '
[download]

I wonder why it is necessary to match something like 'AZZ' and yet grab an undefined value from it, which must later be rationalized Update: to an empty string. (Additionally, the regex Update: first regex of the OP does not match 'AZ', which seems to be required by the OP.)

Wouldn't it make more sense only to grab stuff from strings that match? E.g., "if there is anything between A and Z, it must begin with a space and be followed by zero or more non-Z characters". (Has the advantage of matching 'AZ', no  defined test needed.)

>perl -wMstrict -le
"for (@ARGV) {
   if(/^A ((?: \s [^Z]*)?) Z$/x) {
     print qq{matched '$_'  grabbed '$1'};
     }
   }
"  AZ  AZZ  AXZ  "A ZZ"  "A SOMETHING Z"  ASOMETHINGZ  "A Z"  "A  Z"
matched 'AZ'  grabbed ''
matched 'A SOMETHING Z'  grabbed ' SOMETHING '
matched 'A Z'  grabbed ' '
matched 'A  Z'  grabbed '  '
[download]

Updates:

1. However, the 'Z' still needs to be repeated in the regex! Oh, well...
2. Added "A Z" and "A  Z" test cases to my solution.

I wonder why it is necessary to match something like 'AZZ' and yet grab an undefined value from it.

Good point. This made me rethink my problem. In my case, the grabbed part is not really kept in a variable (I wrote it in that way in the hope to make the whole posting simpler), but within a substituion (to be precise, an insertion): I need to change a text AXZ into AXIZ, where the X is optional. In otherwords, I have to insert I in front of the Z, so in the substitution I use

s/..../A$1IZ/
[download]

, and if I know that $1 is always defined, I don't have to care about interpolating an undefined value. In hindsight, I now see that I should better have written

s/^(A(?:\s.*?)?(Z))/$1I$2/
[download]

. :-(
-- 
Ronald Fischer <ynnor@mm.st>

printf( "\n$_: " ), 
m[A( [^Z]+)Z] and print "'$1'" 
    for 'AZ', 'A SOMETHING Z', 'ASOMETHINGZ', 'A  Z';;

AZ:
A SOMETHING Z: ' SOMETHING '

ASOMETHINGZ:
A  Z: '  '
[download]

But that doesn't match 'AZ', which the OP seems to require, and also doesn't match 'A Z' (single space between first and final characters), which also seems to be required.

A simple variation fixes that:

/A( [^Z]*)?Z/
[download]

It surprises me how many monks in this thread seem to think that expressing the "no Z between ..." condition with .*? is a good idea.

Ah yes, missed that. Maybe this improved version.

printf( "\n$_: " ), 
m[A( [^Z]*|)Z] and print "'$1'" 
    for 'AZ', 'A SOMETHING Z', 'ASOMETHINGZ', 'A Z', 'A  Z';;

AZ: ''

A SOMETHING Z: ' SOMETHING '

ASOMETHINGZ:
A Z: ' '

A  Z: '  '
[download]

---

Examine what is said, not who speaks -- Silence betokens consent -- Love the truth but pardon error.

"Science is about questioning the status quo. Questioning authority".

In the absence of evidence, opinion is indistinguishable from prejudice.

RIP an inspiration; A true Folk's Guy

my @strings = ('AZ', 'A SOMETHING Z', 'ASOMETHINGZ', 'A  Z', 'A ZZ', '
+AA ZZ', 'AAZZ');

for (@strings) {
    if (/A( .*?)?Z/) {
        my $grabbed = $1 // '';
        say "'$_' grabbed '$grabbed'";
    }
    else { say "'$_' did not match" }
}
__END__
'AZ' grabbed ''
'A SOMETHING Z' grabbed ' SOMETHING '
'ASOMETHINGZ' did not match
'A  Z' grabbed '  '
'A ZZ' grabbed ' '
'AA ZZ' grabbed ' '
'AAZZ' grabbed ''
[download]

do what you want?

Update

What should 'A ZZ', 'AAZZ' and 'AA ZZ' match? (added these as test cases)

Contrary to my interpretation of the requirements of the OP, both your regex and the updated regex of rovf's OP allow a 'Z' between the first 'A' and the final 'Z', and also still need to have an undefined  $1 rationalized to an empty string.

What should 'A ZZ', 'AAZZ' and 'AA ZZ' match? (added these as test cases)

They would (and should) not match at all...
-- 
Ronald Fischer <ynnor@mm.st>

Updating my post to accommodate the anchors and your update:

my @strings = ('AZ', 'A SOMETHING Z', 'ASOMETHINGZ', 'A  Z', 'A ZZ', '
+AA ZZ', 'AAZZ', 'A Z');

for (@strings) {
    if (/^A( [^Z]*)?Z$/) {
        my $grabbed = $1 // '';
        say "'$_' grabbed '$grabbed'";
    }
    else { say "'$_' did not match" }
}
__END__
'AZ' grabbed ''
'A SOMETHING Z' grabbed ' SOMETHING '
'ASOMETHINGZ' did not match
'A  Z' grabbed '  '
'A ZZ' did not match
'AA ZZ' did not match
'AAZZ' did not match
'A Z' grabbed ' '
[download]

---

Unless I state otherwise, all my code runs with strict and warnings

I should have taken more notice of the anchors in your OP :(

while (<DATA>) {
  print;
  #s/^A(|\s[^Z]*)Z$/A$1IZ/;
  s/^A(?:|\s[^Z]*)\K(?=Z$)/I/;
  print;
}

__DATA__
AZ
AZZ
A SOMETHING Z
ASOMETHINGZ
A  Z
A ZZ
AAZZ
AA ZZ
[download]

#!/usr/bin/perl -w
use strict;

while (<DATA>) 
{
   chomp;
   my $result = is_match($_);
   defined($result) ? print "$_:\tRESULT=\"$result\"\n"
                    : print "$_:\tRESULT=NO MATCH\n";
}

sub is_match
{
   my $term = shift;
   my $inner = ($term =~ m/^A(.*)Z$/)[0];
   return undef  if (!defined($inner));
   return $inner if $inner eq "";
   return $inner if $inner =~ m/^\s/;
   return undef;
}

=prints:
AZ:    RESULT=""
AZZ:    RESULT=NO MATCH
A SOMETHING Z:    RESULT=" SOMETHING "
ASOMETHINGZ:    RESULT=NO MATCH
A  Z:    RESULT="  "
A ZZ:    RESULT=" Z"
AAZZ:    RESULT=NO MATCH
AA ZZ:    RESULT=NO MATCH
ZA:    RESULT=NO MATCH
=cut

__DATA__
AZ
AZZ
A SOMETHING Z
ASOMETHINGZ
A  Z
A ZZ
AAZZ
AA ZZ
ZA
[download]

sub is_match
{
   my $term = shift;
   my $inner = ($term =~ m/^A(.*)Z$/)[0];
   return undef  if (!defined($inner));
   return undef  if $inner eq "";
   return $inner if $inner =~ m/^\s+\S/;
   return undef;
}
prints:.....
AZ:    RESULT=NO MATCH
AZZ:    RESULT=NO MATCH
A SOMETHING Z:    RESULT=" SOMETHING "
ASOMETHINGZ:    RESULT=NO MATCH
A  Z:    RESULT=NO MATCH
A ZZ:    RESULT=" Z"
AAZZ:    RESULT=NO MATCH
AA ZZ:    RESULT=NO MATCH
ZA:    RESULT=NO MATCH
[download]