my $left_text   = [ qw{ when rome romans} ];
my $right_text  = 'When in Rome, do as the Romans.';
my $regex = join '|', map quotemeta, @$left_text;
   $regex = qr{\b(?:$regex)\b}i;
my $found  = () = $right_text =~ m/$regex/g;

print $found, $/;
[download]

The  $found = () = trick first sets the RHS in list context, and then by obtains the number of elements in the list.

>perl -wMstrict -le
"my $left_text  = [ qw{ when rome romans} ];
 my $right_text = 'When in Rome, do as the Romans.';
 my $regex = qr{ @{[ join '|', @$left_text ]} }xmsi;
 my $found =()= $right_text =~ m/$regex/xmsg;
 print qq{found == $found};
"
found == 3
[download]

The Goatse operator, of course!

my $left_text   = [ qw{ when rome romans} ];
my $right_text  = 'When in Rome, do as the Romans.';
my $regex = join "|", @$left_text;
my $found =()= $right_text =~ m/($regex)/ig;
print "$found\n";
[download]

You're forcing the list of captures into scalar context.

Edit: Thanks for the ++, but AnomalousMonk and moritz posted the same solution earlier than I did. I just added that it had a name.

moritz's solution is NOT the same. Your solution and Anomalous's expect regex patterns in @$left_text, but moritz's solution takes text strings and convert them into regex patterns using quotemeta.

Furthermore, he used \b, so his solution doesn't find "when" in "whenever" like yours does.

Mind you, if the inputs require quotemeta, \b might not work.

Update: Added second and third paragraph.

my $left_text   = [ qw{ when rome romans} ];
my $right_text  = 'When in Rome, Romans do as the Romans do in Rome.';
[download]

Would you expect a result of 3 or of 5 (or something else)? Essentially, do you want a count of all case-insensitive matches or just a count of how many search words matched? If you want the latter, the following would suit your purposes better:

#!/usr/bin/perl
use strict;
use warnings;

my @left_text   = qw{ when rome romans};
my $right_text  = 'When in Rome, Romans do as the Romans do in Rome.';

my $count = '0';
for my $search_text (@left_text) {
    if ($right_text =~ /\Q$search_text\E/i) {
        $count++
    }
}
print "Found = $count\n";
__END__
Found = 3
[download]

Update: And while you're at it, what do you expect for

my $left_text   = [ qw{ when rome romans} ];
my $right_text  = 'When in the Terrordrome, do as the Romans.';
[download]

If you would only expect 2 matches (ignoring that "rome" is in Terrordrome), then you will want word boundary assertions (\b):

#!/usr/bin/perl
use strict;
use warnings;

my @left_text   = qw{ when rome romans};
my $right_text  = 'When in the Terrordrome, do as the Romans.';

my $count = '0';
for my $search_text (@left_text) {
    if ($right_text =~ /\b\Q$search_text\E\b/i) {
        $count++
    }
}
print "Found = $count\n";
__END__
Found = 2
[download]

See perlretut or perlre for more info.

Bound to miss something unspecified :)

#! perl -slw
use strict;

my $left_text   = [ qw{ when rome romans} ];
my $right_text  = 'When in Rome, do as the Romans.';

my $regex = '(?:\b' . join( '\b|\b', map quotemeta, @$left_text ) . '\
+b)';
print $regex;

my $found = () = $right_text =~ m/$regex/ig;

print $found ? 'matched: ' : 'Not matched', $found;

__END__
C:\test>junk42
(?:\bwhen\b|\brome\b|\bromans\b)
matched: 3
[download]